build.gradle

plugins {
    id 'pl.allegro.tech.build.axion-release' version '1.14.2'
    id 'groovy'

}
ext.rundeckVersion='3.0.2-20180803'
defaultTasks 'clean','build'
apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'pl.allegro.tech.build.axion-release'
apply plugin: 'groovy'

sourceCompatibility = 1.8
ext.rundeckPluginVersion= '1.2'

/**
 * Set this to a comma-separated list of full classnames of your implemented Rundeck
 * plugins.
 */
ext.pluginClassNames='io.github.valfadeev.rundeck.plugin.vault.VaultStoragePlugin'


scmVersion {
    ignoreUncommittedChanges = true
    tag {
        prefix = ''
        versionSeparator = ''
    }
}
project.version = scmVersion.version

repositories {
    mavenCentral()
}

configurations{
    //declare custom pluginLibs configuration to include only libs for this plugin
    pluginLibs

    //declare compile to extend from pluginLibs so it inherits the dependencies
    implementation{
        extendsFrom pluginLibs
    }
}

dependencies {
    // add any third-party jar dependencies you wish to include in the plugin
    // using the `pluginLibs` configuration as shown here:

    pluginLibs group: 'com.bettercloud', name: 'vault-java-driver', version: '5.1.0', ext: 'jar'


    //the compile dependency won't add the rundeck-core jar to the plugin contents
    implementation group: 'org.rundeck', name: 'rundeck-core', version: rundeckVersion
    testImplementation(
            [group: 'junit', name: 'junit', version: '4.12', ext: 'jar'],
            [group: 'org.hamcrest', name: 'hamcrest-core', version: '1.3', ext: 'jar'],
            [group: 'org.hamcrest', name: 'hamcrest-library', version: '1.3', ext: 'jar'],
            [group: 'org.mockito', name: 'mockito-core', version: '4.0.0', ext: 'jar'],
            [group: 'net.bytebuddy', name: 'byte-buddy', version: '1.12.1'],
            [group: 'net.bytebuddy', name: 'byte-buddy-agent', version: '1.12.1'],
            [group: 'org.objenesis', name: 'objenesis', version: '3.2']

    )
    testImplementation "org.codehaus.groovy:groovy-all:2.4.15"
    testImplementation "org.spockframework:spock-core:1.0-groovy-2.4"
    testImplementation "cglib:cglib-nodep:2.2.2"

}

// task to copy plugin libs to output/lib dir
task copyToLib(type: Copy) {
    into "$buildDir/output/lib"
    from configurations.pluginLibs
}


jar {
    from "$buildDir/output"
    manifest {
        def libList = configurations.pluginLibs.collect{'lib/'+it.name}.join(' ')
        attributes 'Rundeck-Plugin-Name' : 'Vault Storage'
        attributes 'Rundeck-Plugin-Description' : 'This is a Storage Backend plugin for storing Key Store data in Vault.'
        attributes 'Rundeck-Plugin-Rundeck-Compatibility-Version': '3.0.2+'
        attributes 'Rundeck-Plugin-Tags': 'java,storage,vault'
        attributes 'Rundeck-Plugin-License': 'MIT'
        attributes 'Rundeck-Plugin-Source-Link': 'https://github.com/rundeck-plugins/vault-storage'
        attributes 'Rundeck-Plugin-Target-Host-Compatibility': 'all'
        attributes 'Rundeck-Plugin-Author': 'Rundeck, Inc.'
        attributes 'Rundeck-Plugin-Classnames': pluginClassNames
        attributes 'Rundeck-Plugin-File-Version': version
        attributes 'Rundeck-Plugin-Version': rundeckPluginVersion, 'Rundeck-Plugin-Archive': 'true'
        attributes 'Rundeck-Plugin-Libs': "${libList}"
        attributes 'Main-Class': "io.github.valfadeev.rundeck.plugin.vault.VaultStoragePlugin"
        attributes 'Class-Path': "${libList} lib/rundeck-core-${rundeckVersion}.jar"
    }
}
//set jar task to depend on copyToLib
jar.dependsOn(copyToLib)