run_convect

#
echo " "
echo " =>executing: run_convect"
echo " "
#
# script for testing the "convect.F" module
#
#     options: (must choose only one of these)
#       -Dread_my_grid    : read in your own grid definition
#       -Dgenerate_a_grid : generate a grid based on USER INPUT
#                           in grids.F
#

set OPTIONS = '-Dtest_convect -Dgenerate_a_grid'

set MOM2 = /home/rcp/MOM_2  # base model code
set WORK = TEMP_DIR         # temp directory

set error = false
if (! -r convect.F) then
  echo '=>Error: "convect.F" is not in this UPDATES directory'
  set error = true
endif

if (! -r grids.F) then
  echo '=>Error: "grids.F" is not in this UPDATES directory'
  set error = true
endif

if (! -r size.h) then
  echo '=>Error: "size.h" is not in this UPDATES directory'
  set error = true
endif

if ("$error" == "true") then
  exit
endif

echo "=>Grabbing sources from $MOM2"
mkdir $WORK
cd $WORK
set list = (util.F iomngr.F size_check.F state.F)
foreach file ($list)
  cp $MOM2/$file .
end
cp $MOM2/*.h .
cp ../convect.F .
cp ../grids.F .
cp ../size.h .

echo "=>compiling..."
f77 -P $OPTIONS convect.F; f77 convect.i

echo "=> running...results are being written to results_convect"
a.out > ../results_convect
echo "Done"

cd ../
/bin/rm -r $WORK