eveos.ipxe

#!ipxe

# EVE (Edge Virtualization Engine) OS
# https://lfedge.org/projects/eve/

:eveos

set os EVE OS

menu ${os} Install EVE OS

item --gap WARNING: Installing EVE OS will automatically OVERWRITE all data on disk
item current ${space} ${os} Installer

choose eve_version || goto eve_exit

goto eve_boot

:eve_boot
# you may want to add the following to the kernel command line arguments:
#   * eve_install_disk=XXX (e.g. XXX=mmcblk0)
#   * eve_install_server=XXX (e.g. XXX=zedcloud.hummingbird.zededa.net)
#   * eve_persist_disk=XXX (e.g. XXX=mmcblk0, you can set multiple values here with comma delimiter to use multiple disks).
#
# chain --autofree https://github.com/lf-edge/eve/releases/download/1.2.3/ipxe.efi.cfg
set url https://github.com/lf-edge/eve/releases/download/12.0.2-lts/amd64.
set console console=ttyS0 console=ttyS1 console=ttyS2 console=ttyAMA0 console=ttyAMA1 console=tty0
set eve_args eve_soft_serial=${mac:hexhyp} eve_reboot_after_install getty
set installer_args root=/initrd.image find_boot=netboot overlaytmpfs fastboot

# a few vendor tweaks (mostly an example, although they DO work on Packet.net servers)
iseq ${smbios/manufacturer} Huawei && set console console=ttyAMA0,115200n8 ||
iseq ${smbios/manufacturer} Huawei && set platform_tweaks pcie_aspm=off pci=pcie_bus_perf ||
iseq ${smbios/manufacturer} Supermicro && set console console=ttyS1,115200n8 ||

kernel ${url}kernel ${eve_args} ${installer_args} ${console} ${platform_tweaks} initrd=amd64.initrd.img initrd=amd64.installer.img initrd=amd64.initrd.bits initrd=amd64.rootfs.img
initrd ${url}initrd.img
initrd ${url}installer.img
initrd ${url}initrd.bits
initrd ${url}rootfs.img
boot

goto eve_exit

:eve_exit
clear menu
exit 0