build.gradle

apply plugin: 'java'
apply plugin: 'maven'

defaultTasks 'zip'

group = 'com.linbox'
version = '1.0'

description = 'linbox server'

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {

    mavenLocal()

    maven {
        url 'http://repo.mobimind.net/nexus/content/groups/mobimind-all'
    }

    maven {
        url 'http://repo1.maven.org/maven2'
        artifactUrls 'http://repository.jboss.org/nexus/content/groups/public-jboss'
    }

}
configurations.all {
    // check for updates every build
    resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
}

dependencies {
    compile 'commons-lang:commons-lang:2.6'
    compile 'redis.clients:jedis:2.7.2'
    compile 'com.alibaba:fastjson:1.2.4'
    compile 'joda-time:joda-time:2.8.1'
    compile 'com.google.guava:guava:18.0'

    //slf4j and logback
    compile 'ch.qos.logback:logback-classic:1.1.3'

    // spring
    compile 'org.springframework:spring-core:4.2.2.RELEASE'
    compile 'org.springframework:spring-context:4.2.2.RELEASE'
    compile 'org.springframework:spring-expression:4.2.2.RELEASE'

    // mysql
    compile 'com.zaxxer:HikariCP:2.4.3'
    compile 'org.sql2o:sql2o:1.5.4'
    compile 'mysql:mysql-connector-java:5.1.38'

    //kafka
    compile 'org.apache.kafka:kafka-clients:0.9.0.0'

    //dubbo
    compile group: "com.alibaba", name: "dubbo", version: "2.5.4-SNAPSHOT", changing: true,  {
        exclude module: 'spring'
    }
    compile 'com.github.sgroschupf:zkclient:0.1'

    //netty
    compile 'io.netty:netty-all:4.0.29.Final'


    testCompile 'junit:junit:3.8.1'
}

task copyConfig(type: Copy, dependsOn: 'build') {
    from 'src/main/config'
    from 'src/main/resource'

    into 'build/target/config'
}

task copyBin(type: Copy, dependsOn: 'copyConfig') {
    from 'src/main/bin'
    into 'build/target/bin'
}

task copyLibs(type: Copy, dependsOn: 'copyBin') {
    from configurations.runtime
    from 'build/libs'

    into 'build/target/lib'
}

task zip(type: Zip, dependsOn: 'copyLibs') {
    outputs.upToDateWhen { false }

    from 'build/target'
    into 'linbox_server'
}