build.gradle

plugins {
    id 'maven-publish'
    id 'org.jetbrains.kotlin.jvm' version '1.6.10'
    id "com.github.johnrengelman.shadow" version "7.1.2"
}

// We're keeping this up here so flavor can resolve within the
// parent directory, not the modules
def platforms = ["spigot", "velocity"]
def flavor = fileTree("flavor")

allprojects {
    apply plugin: 'maven-publish'
    apply plugin: 'com.github.johnrengelman.shadow'
    apply plugin: 'org.jetbrains.kotlin.jvm'

    ext {
        // dependency versions
        kotlinVersion = '1.6.10'

        getCurrentShortRevision = {
            new ByteArrayOutputStream().withStream { os ->
                exec {
                    executable = "git"
                    args = ["rev-parse", "HEAD"]
                    standardOutput = os
                }

                return os.toString().trim().substring(0, 8)
            }
        }

        setProperty("revision", getCurrentShortRevision)
    }

    group 'design.lmao.lmaolib'
    version ext.getProperty("revision")

    repositories {
        mavenLocal()
        mavenCentral()

        maven {
            url 'https://jitpack.io'
        }
    }

    dependencies {
        implementation 'org.jetbrains.kotlin:kotlin-stdlib'

        // TODO: replace with dependency version constants
        testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.2'
        testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.2'

        compileOnly 'com.google.code.gson:gson:2.9.0'

        if (platforms.contains(project.name)) {
            implementation flavor
        } else {
            compileOnly flavor
        }
    }

    compileKotlin {
        kotlinOptions.javaParameters = true
        kotlinOptions.jvmTarget = "1.8"
    }

    shadowJar {
        archiveClassifier.set("")

        exclude "**/*.kotlin_metadata"
        exclude "**/*.kotlin_builtins"
        exclude "META-INF/"

        archiveFileName = "dbllib-${project.name}.jar"
    }

    publishing {
        publications {
            shadow(MavenPublication) { publication ->
                project.shadow.component(publication)
            }
        }
    }

    tasks.build.dependsOn(shadowJar)
}