build.gradle

apply plugin: 'groovy'

group 'cz.bh.lisp'
version '1.0.0'

repositories {
    mavenCentral()
}

dependencies {
    compile group: 'org.codehaus.groovy', name: 'groovy', version: '2.5.2'
    compileOnly group: 'org.codehaus.groovy', name: 'groovy-templates', version: '2.5.2'
    // groovy-doc task

    testCompile group: 'junit', name: 'junit', version: '4.12'
}

test {
    testLogging {
        events "failed"
        exceptionFormat "full"
    }
}

// artifacts

jar {
    manifest {
        attributes(
                'Implementation-Title': 'BH Lisp',
                'Implementation-Version': version,
                'Implementation-Vendor': 'Josef Baloun, Patrik Harag',
                'Main-Class': 'cz.bh.lisp.Main',
        )
    }
    doFirst {
        from { configurations.runtime.collect { it.isDirectory() ? it : zipTree(it) } }
    }
}

task sourcesJar(type: Jar, dependsOn:classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

groovydoc {
    includePrivate false
    docTitle 'BH Lisp'
}

task javadocJar(type: Jar, dependsOn:groovydoc) {
    classifier 'javadoc'
    from groovydoc.destinationDir
}

artifacts {
    archives sourcesJar
    archives javadocJar
}