How can I add Value Mappings to a stats panel?

[timeout]

Hi, I would like to add a value mapping to a stat panel. It is for a service status display.
When the query returns:
0 => display text "down" and the background color should be "red", when it returns,
1 => "up" and "green."

I need the JSON snippet to look like this:

{
  ...
  "fieldConfig": {
    "defaults": {
      "mappings": [
        {
          "options": {
            "0": {
              "color": "red",
              "index": 0,
              "text": "down"
            },
            "1": {
              "color": "green",
              "index": 1,
              "text": "up"
            }
          },
          "type": "value"
        }
      ]
      ...
    }
  }
}

I have tried some variations similar to the following, but they don't work:

local g = import 'g.libsonnet';

{
  stat: {
    local stat = g.panel.stat,
    local fieldOverride = stat.fieldOverride,
    // local custom = stat.fieldConfig.defaults.custom,
    local standardOptions = stat.standardOptions,
    local options = stat.options,

    new(title, targets):
      stat.new(title)
      + stat.queryOptions.withTargets(targets)
      + stat.queryOptions.withInterval('1m')
      + options.withColorMode('background_solid')
      + options.withGraphMode('none')
      + standardOptions.threshold.step.withValue(1)
      + standardOptions.threshold.step.withColor('green')
      + standardOptions.withMin(0)
      + standardOptions.withMax(1)
      + standardOptions.withMappings([
        standardOptions.mapping.ValueMap.withOptions([
          { '0': { index: 0, text: 'down', color: 'red' } },
          { '1': { index: 1, text: 'up', color: 'green' } },
          { type: 'value' },
        ]),
      ]),
  },
}

Do I need to use an withOverride, or withType somehow? Thanks!

[timeout]

Hi, one solution is just to add the JSON directly:

local upDownMapping = {
        fieldConfig: {
          defaults: {
            mappings: [
              {
                options: {
                  '0': {
                    color: 'red',
                    index: 0,
                    text: 'down',
                  },
                  '1': {
                    color: 'green',
                    index: 1,
                    text: 'up',
                  },
                },
                type: 'value',
              },
            ],
          },
        },
      };

{
  stat: {
    local stat = g.panel.stat,
    local fieldOverride = stat.fieldOverride,
    // local custom = stat.fieldConfig.defaults.custom,
    local standardOptions = stat.standardOptions,
    local options = stat.options,

    new(title, targets):
      stat.new(title)
      + stat.queryOptions.withTargets(targets)
      + stat.queryOptions.withInterval('1m')
      + options.withColorMode('background_solid')
      + options.withGraphMode('none')
      + standardOptions.threshold.step.withValue(1)
      + standardOptions.threshold.step.withColor('green')
      + standardOptions.withMin(0)
      + standardOptions.withMax(1)
      + upDownMapping
  },
}

This doesn't feel like the right approach, but it works for now. I don't understand the concept behind how the library works.

[hlolli]

The error messages aren't very good, but I discovered with trial and error, that it's possible to make it work like this

+ g.panel.stat.standardOptions.withMappings([{
    type: 'value',
    options: {
      '0': {
        color: 'red',
        index: 1,
        text: 'server.com is DOWN',
      },
      '1': {
        color: 'green',
        index: 0,
        text: 'server.com is UP',
      },
    },
  }])

[timeout]

Thanks hlolli!