settings.gradle.kts

/*
 * Copyright 2024 Erfan Sn
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

pluginManagement {
    repositories {
        gradlePluginPortal()
        google()
        mavenCentral()
    }
}

dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        google()
        mavenCentral()
    }
}

enableFeaturePreview("TYPESAFE_PROJECT_ACCESSORS")

rootProject.name = "ComposableScreens"

includeBuild("build-logic")

private fun subprojects(path: String) =
    file(path)
        .listFiles()
        ?.filter {
            it.isDirectory && it.listFiles()?.any { file -> file.name == "build.gradle.kts" } ?: false
        }?.map {
            "${path.replace('/', ':')}:${it.name}"
        }.orEmpty()

include("app")
include("common")
include(subprojects("auto-nav-graph-wiring-processors"))
include(subprojects("category/travel"))
include(subprojects("category/food"))