build.gradle

/*
 * This file is part of dependency-check-gradle.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 *
 * Copyright (c) 2015 Wei Ma. All Rights Reserved.
 */

ext {
    odcVersion = '7.0.4'
    slackWebhookVersion = '1.4.0'
    spockCoreVersion = '1.1-groovy-2.4'
}

group = 'org.owasp'
version = "${odcVersion}.2-SNAPSHOT"

buildscript {
    repositories {
        mavenLocal()
        maven {
            url 'https://plugins.gradle.org/m2/'
        }
    }
    dependencies {
        classpath "com.gradle.publish:plugin-publish-plugin:0.11.0"
    }
}

apply plugin: 'groovy'
apply plugin: 'java-gradle-plugin'
apply plugin: 'idea'
apply plugin: 'eclipse'
apply plugin: 'maven-publish'
apply plugin: 'signing'
apply plugin: 'project-report'
apply plugin: 'build-dashboard'
apply plugin: 'com.gradle.plugin-publish'

repositories {
    mavenLocal()
    maven {
        name 'OWASP dependency-check snapshot'
        url 'https://oss.sonatype.org/content/repositories/snapshots'
    }
    mavenCentral()
}

dependencies {
    implementation(
            localGroovy(),
            gradleApi(),
            'org.codehaus.groovy:groovy-yaml:3.0.10',
            'com.github.groovy-wslite:groovy-wslite:1.1.3'
    )
    api(
            "org.owasp:dependency-check-core:$odcVersion",
            "org.owasp:dependency-check-utils:$odcVersion",
            "net.gpedro.integrations.slack:slack-webhook:$slackWebhookVersion"
    )

    testImplementation gradleTestKit()
    testImplementation("org.spockframework:spock-core:$spockCoreVersion") {
        exclude module: 'groovy-all'
    }
}

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8

    withJavadocJar()
    withSourcesJar()
}

javadoc {
    if(JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}

publishing {
    publications {
        pluginPublication (MavenPublication) {
            groupId "$group"
            artifactId 'dependency-check-gradle'
            version "$version"
            from components.java
            pom {
                name = 'dependency-check-gradle'
                description = 'OWASP dependency-check gradle plugin is a software ' +
                        'composition analysis tool used to find known vulnerable dependencies.'

                url = 'https://jeremylong.github.io/DependencyCheck/'

                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'https://github.com/dependency-check/dependency-check-gradle/blob/main/LICENSE.txt'
                    }
                }
                developers {
                    developer {
                        id = 'jlong'
                        name = 'Jeremy Long'
                        email = 'jeremy.long@owasp.org'
                    }
                }
                scm {
                    url = 'https://github.com/dependency-check/dependency-check-gradle'
                    connection = 'scm:git:https://github.com/dependency-check/dependency-check-gradle.git'
                    developerConnection = 'scm:git:https://github.com/dependency-check/dependency-check-gradle.git'
                }
            }
        }
    }
    repositories {
        maven {
            url "https://oss.sonatype.org/service/local/staging/deploy/maven2"
            credentials {
                username sonatypeUsername
                password sonatypePassword
            }
        }
    }
}

signing {
    sign publishing.publications.pluginPublication
}

pluginBundle {
    website = 'http://jeremylong.github.io/DependencyCheck/dependency-check-gradle/index.html'
    vcsUrl = 'https://github.com/dependency-check/dependency-check-gradle/'
    description = 'A software composition analysis plugin that identifies known vulnerable dependencies used by the project.'
    tags = ['OWASP', 'dependency-check', 'gradle-plugin', 'software-composition-analysis', 'vulnerability-detection', 'security']

    plugins {
        dependencyCheck {
            id = 'org.owasp.dependencycheck'
            displayName = 'OWASP dependency-check-gradle plugin'
        }
    }
    mavenCoordinates {
        groupId = "org.owasp"
    }
}

publish.dependsOn publishPlugins

defaultTasks 'build'