build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    ext {
        sdkCompileVersion = 28
        sdkMinVersion = 17
        sdkTargetVersion = 28
        buildTools = '29.0.3'

        coreVersion = project.rootProject.file('.lib-version').getText('UTF-8')

        coreGroupId = 'com.botnerd.core'

        publishGroupId = coreGroupId

        libraryArtifact = 'android-core'
        libraryGroup = 'com.botnerd.core'
        libraryName = 'android-core'
        libraryDescription = 'A set of helper methods for Android apps'

        siteUrl = 'https://github.com/botnerd/android-core'
        scmConnection = 'scm:git:github.com/botnerd/android-core.git'
        scmDeveloperConnection = 'scm:git:github.com/botnerd/android-core.git'
        scmUrl = 'https://github.com/botnerd/android-core.git'

        developerId = 'botnerd'
        developerName = 'Tim Judkins'
        developerEmail = 'tim@botnerd.com'

        licenseName = 'The Apache Software License, Version 2.0'
        licenseUrl = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
        allLicenses = ["Apache-2.0"]

        androidx_appcompat_version = '1.2.0'

        googleServicesVersion = '4.2.0'

        kotlinVersion = '1.4.10'
        navVersion = "2.0.0"

        supportLibVersion = '1.0.2'
        legacySupportLibVersion = '1.0.0'
        materialLibVersion = '1.2.1'
        recyclerLibVersion = '1.1.0'
        browserLibVersion = '1.2.0'
        mediaLibVersion = '1.0.0'

        // Networking
        retrofitVersion = '2.9.0'
        okhttpVersion = '4.9.0'
        okioVersion = '2.2.2'

        // Timber logging util
        timberVersion = '4.7.1'

        // Barcode Support
        zxingCoreVersion = '3.4.1' // Higher versions support Android SDK 19+
        zxingAndroidEmbeddedVersion = '3.5.0'

        junitVersion = '4.13.1'
        androidTestVersion = '1.1.2'
        espressoVersion = '3.1.0'

    }
    repositories {
        jcenter()
        google()
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:4.1.0'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

plugins {
    id("io.github.gradle-nexus.publish-plugin") version "1.0.0"
}

allprojects {
    repositories {
        jcenter()
        google()
        mavenCentral()
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

gradle.projectsEvaluated {
    tasks.withType(JavaCompile) {
        options.compilerArgs << "-Xmaxerrs" << "1000" // or whatever number you want
    }
}

subprojects {
    tasks.withType(Javadoc).all { enabled = false }
}

File ossrhProp = project.rootProject.file('ossrh.properties')
if (ossrhProp.exists()) {
    Properties p = new Properties()
    p.load(new FileInputStream(ossrhProp))
    p.each { name, value ->
        ext[name] = value
    }

    group coreGroupId
    version coreVersion

    nexusPublishing {
        repositories {
            sonatype {
                username = ossrhUsername
                password = ossrhPassword
            }
        }
    }
}