build.gradle

plugins {
    id 'groovy'
    id 'maven'
    id 'signing'
}

dependencies {
    implementation gradleApi()
    implementation localGroovy()
}

repositories {
    mavenCentral()
}

sourceCompatibility='1.8'
targetCompatibility='1.8'

task javadocJar(type: Jar, dependsOn: groovydoc) {
    classifier = 'javadoc'
    from "${buildDir}/docs/groovydoc"
}

task sourcesJar(type: Jar) {
    from sourceSets.main.groovy.srcDirs
    classifier = 'sources'
}

task setGradleVersion(type: Wrapper) {
    gradleVersion = '6.1'
}

artifacts {
    archives jar
    archives javadocJar
    archives sourcesJar

}

signing {
    required {gradle.taskGraph.hasTask("uploadArchives") }
    sign configurations.archives
}



if (project.hasProperty('publish_repository')){
    uploadArchives {
        it.dependsOn(signArchives)
        repositories {
            mavenDeployer {
                beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
                repository(url: publish_repository) {
                    authentication(userName: publish_user, password: publish_password)
                }
                pom.project {
                    licenses {
                        license {
                            name 'GNU Lesser General Public License'
                            url 'http://www.gnu.org/licenses/lgpl.html'
                            distribution 'repo'
                        }
                    }
                    organization {
                        name 'Alkacon Software'
                        url 'http://www.alkacon.com'
                    }
                    developers {
                        developer {
                            name 'Alkacon Software'
                            url 'http://www.alkacon.com'
                        }
                    }
                    url 'http://www.opencms.org'
                    name 'OpenCms Modules Gradle Plugin'
                    description 'This Gradle plugin can be used to build modules for OpenCms.'
                    scm {
                        url 'scm:git@github.com:alkacon/opencms-gradle-plugin.git'
                        connection 'scm:git@github.com:alkacon/opencms-gradle-plugin.git'
                        developerConnection 'scm:git@github.com:alkacon/opencms-gradle-plugin.git'
                    }
                }
            }
        }
    }
}