-
-
Notifications
You must be signed in to change notification settings - Fork 3
/
SimpleMessages.pas
1829 lines (1608 loc) · 67.4 KB
/
SimpleMessages.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
{-------------------------------------------------------------------------------
This Source Code Form is subject to the terms of the Mozilla Public
License, v. 2.0. If a copy of the MPL was not distributed with this
file, You can obtain one at http://mozilla.org/MPL/2.0/.
-------------------------------------------------------------------------------}
{===============================================================================
Simple messages
This unit provides means of simple inter-thread and also inter-process
message-based communication.
It was created for use in Linux as a functional replacement of Windows
message system (SendMessage, PostMessage, GetMessage, ...).
There are, at this point, no performance optimizations in place, therefore
its use should be limited only to sporadic notifications and exchange of
very small amount of data (what can fit into the parameters).
Both asynchronous (PostMessage) and synchronous (SendMessage) sending is
fully supported.
WARNING - sending a message from handler that is processing received
synchronous (sent) message is possible, but it creates a
complex indirect recursion. This, when not checked, can lead to
a stack overflow. Be aware of this.
To fetch and dispatch/process any incoming messages, call PeekMessages
(non-blocking) or GetMessages (blocks until a message is received or a
given timeout elapses).
Also, there are two ways how to use this unit - either create an instance
of TSimpleMessagesClient class and call its methods, or use provided
procedural interface (standalone functions InitMessages, SendMessage, ...).
WARNING - when using an TSimpleMessagesClient instance, do creation and
all method calls within a single thread.
For more information on this unit, contact the author or consult with the
source code.
Version 1.0 alpha 3 (requires extensive testing) (2024-05-03)
Last change 2024-10-04
©2022-2024 František Milt
Contacts:
František Milt: [email protected]
Support:
If you find this code useful, please consider supporting its author(s) by
making a small donation using the following link(s):
https://www.paypal.me/FMilt
Changelog:
For detailed changelog and history please refer to this git repository:
github.com/TheLazyTomcat/Lib.SimpleMessages
Dependencies:
AuxClasses - github.com/TheLazyTomcat/Lib.AuxClasses
* AuxExceptions - github.com/TheLazyTomcat/Lib.AuxExceptions
AuxTypes - github.com/TheLazyTomcat/Lib.AuxTypes
BitVector - github.com/TheLazyTomcat/Lib.BitVector
* LinSyncObjs - github.com/TheLazyTomcat/Lib.LinSyncObjs
MemVector - github.com/TheLazyTomcat/Lib.MemVector
SharedMemoryStream - github.com/TheLazyTomcat/Lib.SharedMemoryStream
* WinSyncObjs - github.com/TheLazyTomcat/Lib.WinSyncObjs
Library AuxExceptions is required only when rebasing local exception classes
(see symbol SimpleMessages_UseAuxExceptions for details).
Library LinSyncObjs is required only when compiling for Linux OS.
Library WinSyncObjs is required only when compiling for Windows OS.
Library AuxExceptions might also be required as an indirect dependency.
Indirect dependencies:
BasicUIM - github.com/TheLazyTomcat/Lib.BasicUIM
BinaryStreamingLite - github.com/TheLazyTomcat/Lib.BinaryStreamingLite
BitOps - github.com/TheLazyTomcat/Lib.BitOps
HashBase - github.com/TheLazyTomcat/Lib.HashBase
InterlockedOps - github.com/TheLazyTomcat/Lib.InterlockedOps
ListSorters - github.com/TheLazyTomcat/Lib.ListSorters
NamedSharedItems - github.com/TheLazyTomcat/Lib.NamedSharedItems
SHA1 - github.com/TheLazyTomcat/Lib.SHA1
SimpleCPUID - github.com/TheLazyTomcat/Lib.SimpleCPUID
SimpleFutex - github.com/TheLazyTomcat/Lib.SimpleFutex
StaticMemoryStream - github.com/TheLazyTomcat/Lib.StaticMemoryStream
StrRect - github.com/TheLazyTomcat/Lib.StrRect
UInt64Utils - github.com/TheLazyTomcat/Lib.UInt64Utils
WinFileInfo - github.com/TheLazyTomcat/Lib.WinFileInfo
===============================================================================}
unit SimpleMessages;
{
SimpleMessages_UseAuxExceptions
If you want library-specific exceptions to be based on more advanced classes
provided by AuxExceptions library instead of basic Exception class, and don't
want to or cannot change code in this unit, you can define global symbol
SimpleMessages_UseAuxExceptions to achieve this.
}
{$IF Defined(SimpleMessages_UseAuxExceptions)}
{$DEFINE UseAuxExceptions}
{$IFEND}
//------------------------------------------------------------------------------
{$IF Defined(WINDOWS) or Defined(MSWINDOWS)}
{$DEFINE Windows}
{$ELSEIF Defined(LINUX) and Defined(FPC)}
{$DEFINE Linux}
{$ELSE}
{$MESSAGE FATAL 'Unsupported operating system.'}
{$IFEND}
{$IFDEF FPC}
{$MODE ObjFPC}
{$MODESWITCH ClassicProcVars+}
{$MODESWITCH DuplicateLocals+}
{$DEFINE FPC_DisableWarns}
{$MACRO ON}
{$ENDIF}
{$H+}
interface
uses
SysUtils, {$IFNDEF Windows}BaseUnix, {$ENDIF}
AuxTypes, AuxClasses, BitVector, MemVector, SharedMemoryStream,
{$IFDEF Windows}WinSyncObjs{$ELSE}LinSyncObjs{$ENDIF}
{$IFDEF UseAuxExceptions}, AuxExceptions{$ENDIF};
{===============================================================================
Library-specific exceptions
===============================================================================}
type
ESMException = class({$IFDEF UseAuxExceptions}EAEGeneralException{$ELSE}Exception{$ENDIF});
ESMSystemError = class(ESMException);
ESMInvalidValue = class(ESMException);
ESMLimitMismatch = class(ESMException);
ESMOutOfResources = class(ESMException);
ESMIndexOutOfBounds = class(ESMException);
ESMNoMessageClient = class(ESMException);
{===============================================================================
Common types and constants
===============================================================================}
{-------------------------------------------------------------------------------
Common types and constants - public
-------------------------------------------------------------------------------}
type
TSMClientID = UInt16;
TSMMessageParam = UInt64;
TSMMessageResult = TSMMessageParam; // must be the same type as for parameter
TSMMessage = record
Sender: TSMClientID;
Param1: TSMMessageParam;
Param2: TSMMessageParam;
Result: TSMMessageResult;
end;
TSMDispatchFlag = (dfSentMessage,dfBroadcastedMessage,dfDirectDispatch,
dfStopDispatching);
TSMDispatchFlags = set of TSMDispatchFlag;
type
TSMMessageEvent = procedure(Sender: TObject; var Msg: TSMMessage; var Flags: TSMDispatchFlags) of object;
TSMMessageCallback = procedure(Sender: TObject; var Msg: TSMMessage; var Flags: TSMDispatchFlags);
const
SM_MAXCLIENTS_DEF = 128;
SM_MAXMESSAGES_DEF = 8192; // this must be larger than or equal to SM_MAXCLIENTS_DEF
CLIENTID_BROADCAST = $FFFF;
INFINITE = UInt32(-1); // infinite timeout
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
type
TSMExtraInfo = record
ClientCount: Integer;
MaxClients: Integer;
MessageCount: Integer;
MaxMessages: Integer;
SharedMemorySize: TMemSize;
FetchedSentMessagesCount: Integer;
FetchedPostedMessagesCount: Integer;
end;
{-------------------------------------------------------------------------------
Common types and constants - internal
-------------------------------------------------------------------------------}
type
{$IFDEF Windows}
TSMCrossHandle = UInt64;
{$ENDIF}
TSMMessageIndex = Int32;
TSMMessageFlags = UInt32;
TSMMessageTimestamp = Int64;
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
type
TSMShMemClients = packed record
Count: Int32;
MessageSlotWaitCount: Int32;
MapOffset: UInt32;
ArrayOffset: UInt32;
end;
PSMShMemClients = ^TSMShMemClients;
TSMShMemMessages = packed record
Count: Int32;
ArrayOffset: UInt32;
// linked list indices
FirstFree: TSMMessageIndex;
LastFree: TSMMessageIndex;
FirstUsed: TSMMessageIndex;
LastUsed: TSMMessageIndex;
end;
PSMShMemMessages = ^TSMShMemMessages;
TSMShMemHead = packed record
Initialized: Boolean;
MaxClients: Int32;
MaxMessages: Int32;
Clients: TSMShMemClients;
Messages: TSMShMemMessages;
end;
PSMShMemHead = ^TSMShMemHead;
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
type
TSMShMemClient = packed record
Flags: UInt32;
{$IFDEF Windows}
Identifier: TGUID;
ProcessID: DWORD;
Synchronizer: TSMCrossHandle;
ThreadID: DWORD;
{$ELSE}
Synchronizer: TLSOSimpleEvent;
ThreadID: pid_t;
{$ENDIF}
T2TWakeupCode: UInt64;
T2TWakeupData: UInt64;
end;
PSMShMemClient = ^TSMShMemClient;
TSMShMemMessage = packed record
Sender: TSMClientID;
Recipient: TSMClientID;
Flags: TSMMessageFlags;
Timestamp: TSMMessageTimestamp;
P1_Result: TSMMessageParam;
P2_Counter: TSMMessageParam;
MasterMsg: TSMMessageIndex;
// linked list indices...
Index: TSMMessageIndex;
Prev: TSMMessageIndex;
Next: TSMMessageIndex;
end;
PSMShMemMessage = ^TSMShMemMessage;
{$IFDEF Windows}
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
type
TSMClientSynchonizer = record
Assigned: Boolean;
Identifier: TGUID;
Synchronizer: TEvent;
end;
TSMClientSynchonizers = array of TSMClientSynchonizer;
{$ENDIF}
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
type
TSMFetchMessagesResult = (lmrSentMessage,lmrPostedMessage);
TSMFetchMessagesResults = set of TSMFetchMessagesResult;
{===============================================================================
--------------------------------------------------------------------------------
TSMMessageVector
--------------------------------------------------------------------------------
===============================================================================}
{===============================================================================
TSMMessageVector - class declaration
===============================================================================}
type
TSMMessageVector = class(TMemVector)
protected
Function GetItem(Index: Integer): TSMShMemMessage; virtual;
procedure SetItem(Index: Integer; Value: TSMShMemMessage); virtual;
Function ItemCompare(Item1,Item2: Pointer): Integer; override;
public
constructor Create; overload;
constructor Create(Memory: Pointer; Count: Integer); overload;
Function First: TSMShMemMessage; reintroduce;
Function Last: TSMShMemMessage; reintroduce;
Function IndexOf(Item: TSMShMemMessage): Integer; reintroduce;
Function Find(Item: TSMShMemMessage; out Index: Integer): Boolean; reintroduce;
Function Add(Item: TSMShMemMessage): Integer; reintroduce;
procedure Insert(Index: Integer; Item: TSMShMemMessage); reintroduce;
Function Remove(Item: TSMShMemMessage): Integer; reintroduce;
Function Extract(Item: TSMShMemMessage): TSMShMemMessage; reintroduce;
property Items[Index: Integer]: TSMShMemMessage read GetItem write SetItem; default;
end;
{===============================================================================
--------------------------------------------------------------------------------
TSimpleMessagesClient
--------------------------------------------------------------------------------
===============================================================================}
{===============================================================================
TSimpleMessagesClient - class declaration
===============================================================================}
type
TSimpleMessagesClient = class(TCustomObject)
protected
fThreadID: {$IFDEF Windows}DWORD{$ELSE}pid_t{$ENDIF};
fIsFounder: Boolean;
fClientID: TSMClientID;
fSharedMemory: TSharedMemory;
fShMemHead: PSMShMemHead;
fShMemClient: PSMShMemClient;
fShMemClientMap: Pointer;
fShMemClientArr: Pointer;
fShMemMessageArr: Pointer;
fClientMap: TBitVectorStatic;
fSynchronizer: {$IFDEF Windows}TEvent{$ELSE}PLSOSimpleEvent{$ENDIF};
fFetchedSentMessages: TSMMessageVector;
fFetchedPostedMessages: TSMMessageVector;
{$IFDEF Windows}
fClientSyncs: TSMClientSynchonizers;
{$ENDIF}
fOnMessageEvent: TSMMessageEvent;
fOnMessageCallback: TSMMessageCallback;
// geting item pointers
Function GetClientArrayItemPtr(ClientIndex: Integer): PSMShMemClient; virtual;
Function GetMessageArrayItemPtr(MessageIndex: TSMMessageIndex): PSMShMemMessage; virtual;
Function GetMessageArrayNextItemPtr(MessageItem: PSMShMemMessage): PSMShMemMessage; virtual; // does not check bounds
// internal workings
procedure DecoupleMessage(MessageIndex: TSMMessageIndex); virtual; // NL (= does not lock shared memory, but expects it to be locked)
Function AddMessage(const Msg: TSMShMemMessage): TSMMessageIndex; virtual; // NL
procedure RemoveMessage(MessageIndex: TSMMessageIndex); virtual; // NL
procedure ReleaseSentMessage(MessageIndex: TSMMessageIndex; Processed: Boolean; MsgResult: TSMMessageResult); virtual; // NL
procedure WakeClient(ClientIndex: Integer; SetFlags: UInt32); virtual; // NL
procedure ThreadToThreadWakeupCall(ClientIndex: Integer); virtual; // NL
procedure WakeClientsMsgSlots; virtual; // NL
procedure WaitMessageSlots(ClientsCount: Boolean); virtual; // NL
Function SendSinglecast(Recipient: TSMClientID; Param1, Param2: TSMMessageParam): TSMMessageResult; virtual;
Function SendBroadcast(Param1, Param2: TSMMessageParam): TSMMessageResult; virtual;
Function PostSinglecast(Recipient: TSMClientID; Param1, Param2: TSMMessageParam): Boolean; virtual;
Function PostBroadcast(Param1, Param2: TSMMessageParam): Boolean; virtual;
Function WaitMessages(Timeout: UInt32): Boolean; virtual;
Function FetchMessages: TSMFetchMessagesResults; virtual;
Function DirectDispatchMessage(var Msg: TSMShMemMessage): TSMMessageResult; virtual;
procedure DispatchSentMessages; virtual;
procedure DispatchPostedMessages; virtual;
Function InternalPeekMessages: Boolean; virtual;
procedure ThreadToThreadWakeup; virtual;
// events firing
procedure DoMessage(var Msg: TSMMessage; var Flags: TSMDispatchFlags); virtual;
// object init/final
procedure Initialize(MaxClients,MaxMessages: Integer; const NameSpace: String); virtual;
procedure Finalize; virtual;
// some utilities
Function LowClientIndex: Integer; virtual;
Function HighClientIndex: Integer; virtual;
Function CheckClientIndex(ClientIndex: Integer): Boolean; virtual;
Function CheckClientID(ClientID: TSMClientID): Boolean; virtual;
Function LowMessageIndex: TSMMessageIndex; virtual;
Function HighMessageIndex: TSMMessageIndex; virtual;
Function CheckMessageIndex(MessageIndex: TSMMessageIndex): Boolean; virtual;
public
constructor Create(MaxClients,MaxMessages: Integer; const NameSpace: String = ''); overload;
constructor Create(const NameSpace: String = ''); overload;
destructor Destroy; override;
Function SendMessage(Recipient: TSMClientID; Param1, Param2: TSMMessageParam): TSMMessageResult; virtual;
Function PostMessage(Recipient: TSMClientID; Param1, Param2: TSMMessageParam): Boolean; virtual;
procedure GetMessages(Timeout: UInt32 = INFINITE); virtual;
procedure PeekMessages; virtual;
Function GetExtraInfo: TSMExtraInfo; virtual;
property IsFounder: Boolean read fIsFounder;
property ClientID: TSMClientID read fClientID;
property OnMessageCallback: TSMMessageCallback read fOnMessageCallback write fOnMessageCallback;
property OnMessageEvent: TSMMessageEvent read fOnMessageEvent write fOnMessageEvent;
property OnMessage: TSMMessageEvent read fOnMessageEvent write fOnMessageEvent;
end;
{===============================================================================
--------------------------------------------------------------------------------
Procedural interface
--------------------------------------------------------------------------------
===============================================================================}
{===============================================================================
Procedural interface - declaration
===============================================================================}
procedure InitMessages(Handler: TSMMessageCallback; MaxClients,MaxMessages: Integer; const NameSpace: String = ''); overload;
procedure InitMessages(Handler: TSMMessageEvent; MaxClients,MaxMessages: Integer; const NameSpace: String = ''); overload;
procedure InitMessages(Handler: TSMMessageCallback; const NameSpace: String = ''); overload;
procedure InitMessages(Handler: TSMMessageEvent; const NameSpace: String = ''); overload;
procedure FinalMessages;
procedure SetMessageHandler(Handler: TSMMessageCallback); overload;
procedure SetMessageHandler(Handler: TSMMessageEvent); overload;
Function ActiveMessages: Boolean;
//------------------------------------------------------------------------------
Function SendMessage(Recipient: TSMClientID; Param1, Param2: TSMMessageParam): TSMMessageResult;
Function PostMessage(Recipient: TSMClientID; Param1, Param2: TSMMessageParam): Boolean;
procedure GetMessages(Timeout: UInt32 = INFINITE);
procedure PeekMessages;
implementation
uses
{$IFDEF Windows}Windows,{$ELSE}Linux, SysCall, {$ENDIF} Math;
{$IFDEF FPC_DisableWarns}
{$DEFINE FPCDWM}
{$DEFINE W4055:={$WARN 4055 OFF}} // Conversion between ordinals and pointers is not portable
{$ENDIF}
{===============================================================================
Auxiliary functions
===============================================================================}
Function GetTimestamp: TSMMessageTimestamp;
{$IFDEF Windows}
begin
Result := 0;
If not QueryPerformanceCounter(Result) then
raise ESMSystemError.CreateFmt('GetTimestamp: Cannot obtain time stamp (%d).',[GetLastError]);
{$ELSE}
var
Time: TTimeSpec;
begin
If clock_gettime(CLOCK_MONOTONIC_RAW,@Time) = 0 then
Result := (Int64(Time.tv_sec) * 1000000000) + Time.tv_nsec
else
raise ESMSystemError.CreateFmt('GetTimestamp: Cannot obtain time stamp (%d).',[errno]);
{$ENDIF}
Result := Result and $7FFFFFFFFFFFFFFF; // mask out sign bit
end;
//------------------------------------------------------------------------------
Function GetElapsedMillis(StartTime: TSMMessageTimestamp): UInt32;
var
CurrentTime: TSMMessageTimestamp;
Temp: Int64;
begin
CurrentTime := GetTimestamp;
If CurrentTime >= StartTime then
begin
{$IFDEF Windows}
Temp := 1;
If QueryPerformanceFrequency(Temp) then
Temp := Trunc(((CurrentTime - StartTime) / Temp) * 1000)
else
raise ESMSystemError.CreateFmt('GetElapsedMillis: Cannot obtain timer frequency (%d).',[GetLastError]);
{$ELSE}
Temp := (CurrentTime - StartTime) div 1000000; // stamps are in ns, convert to ms
{$ENDIF}
If Temp < INFINITE then
Result := UInt32(Temp)
else
Result := INFINITE;
end
else Result := INFINITE;
end;
//------------------------------------------------------------------------------
Function ConstructMessage(Sender,Recipient: TSMClientID; Flags: TSMMessageFlags; P1,P2: TSMMessageParam; MasterMsg: TSMMessageIndex): TSMShMemMessage;
begin
Result.Sender := Sender;
Result.Recipient := Recipient;
Result.Flags := Flags;
Result.Timestamp := GetTimestamp;
Result.P1_Result := P1;
Result.P2_Counter := P2;
Result.MasterMsg := MasterMsg;
Result.Index := -1;
Result.Prev := -1;
Result.Next := -1;
end;
//------------------------------------------------------------------------------
{$IFNDEF Windows}
Function gettid: pid_t;
begin
Result := do_syscall(syscall_nr_gettid);
end;
{$ENDIF}
{===============================================================================
--------------------------------------------------------------------------------
TSMMessageVector
--------------------------------------------------------------------------------
===============================================================================}
{===============================================================================
TSMMessageVector - class implementation
===============================================================================}
{-------------------------------------------------------------------------------
TSMMessageVector - protected methods
-------------------------------------------------------------------------------}
Function TSMMessageVector.GetItem(Index: Integer): TSMShMemMessage;
begin
Result := TSMShMemMessage(GetItemPtr(Index)^);
end;
//------------------------------------------------------------------------------
procedure TSMMessageVector.SetItem(Index: Integer; Value: TSMShMemMessage);
begin
SetItemPtr(Index,@Value);
end;
//------------------------------------------------------------------------------
Function TSMMessageVector.ItemCompare(Item1,Item2: Pointer): Integer;
begin
{
Order messages only by time.
Because messages are traversed from high index to low, the sorting is done in
reverse (from higher timestamp to lower, so the older are dispatched first).
}
If TSMShMemMessage(Item1^).Timestamp < TSMShMemMessage(Item2^).Timestamp then
Result := +1
else If TSMShMemMessage(Item1^).Timestamp > TSMShMemMessage(Item2^).Timestamp then
Result := -1
else
Result := 0;
end;
{-------------------------------------------------------------------------------
TSMMessageVector - public methods
-------------------------------------------------------------------------------}
constructor TSMMessageVector.Create;
begin
inherited Create(SizeOf(TSMShMemMessage));
ShrinkMode := smKeepCap;
end;
// --- --- --- --- --- --- --- --- --- --- --- --- ---
constructor TSMMessageVector.Create(Memory: Pointer; Count: Integer);
begin
inherited Create(Memory,Count,SizeOf(TSMShMemMessage));
end;
//------------------------------------------------------------------------------
Function TSMMessageVector.First: TSMShMemMessage;
begin
Result := TSMShMemMessage(inherited First^);
end;
//------------------------------------------------------------------------------
Function TSMMessageVector.Last: TSMShMemMessage;
begin
Result := TSMShMemMessage(inherited Last^);
end;
//------------------------------------------------------------------------------
Function TSMMessageVector.IndexOf(Item: TSMShMemMessage): Integer;
begin
Result := inherited IndexOf(@Item);
end;
//------------------------------------------------------------------------------
Function TSMMessageVector.Find(Item: TSMShMemMessage; out Index: Integer): Boolean;
begin
Result := inherited Find(@Item,Index);
end;
//------------------------------------------------------------------------------
Function TSMMessageVector.Add(Item: TSMShMemMessage): Integer;
begin
Result := inherited Add(@Item);
end;
//------------------------------------------------------------------------------
procedure TSMMessageVector.Insert(Index: Integer; Item: TSMShMemMessage);
begin
inherited Insert(Index,@Item);
end;
//------------------------------------------------------------------------------
Function TSMMessageVector.Remove(Item: TSMShMemMessage): Integer;
begin
Result := inherited Remove(@Item);
end;
//------------------------------------------------------------------------------
Function TSMMessageVector.Extract(Item: TSMShMemMessage): TSMShMemMessage;
var
TempPtr: Pointer;
begin
TempPtr := inherited Extract(@Item);
If Assigned(TempPtr) then
Result := TSMShMemMessage(TempPtr^)
else
FillChar(Addr(Result)^,SizeOf(Result),0);
end;
{===============================================================================
--------------------------------------------------------------------------------
TSimpleMessagesClient
--------------------------------------------------------------------------------
===============================================================================}
const
SM_SHAREDMEM_PREFIX = 'sm_shrdmem_';
SM_CLIENTFLAG_RECVSMSG = UInt32($00000001); // received sent message(s)
SM_CLIENTFLAG_RECVPMSG = UInt32($00000002); // received posted message(s)
SM_CLIENTFLAG_RECVMSG = UInt32(SM_CLIENTFLAG_RECVSMSG or SM_CLIENTFLAG_RECVPMSG); // received a message
SM_CLIENTFLAG_MSGSLTWT = UInt32($00000004); // client is waiting for a free message slot
SM_MSGFLAG_SENT = UInt32($00000001); // message was sent, not posted
SM_MSGFLAG_BROADCAST = UInt32($00000002); // broadcasted message
SM_MSGFLAG_MASTER = UInt32($00000004); // sent broadcasted master message
SM_MSGFLAG_FETCHED = UInt32($00000008); // message is fetched but not removed (sent messages, prevents refetching)
SM_MSGFLAG_RELEASED = UInt32($00000010); // sender is released from waiting
SM_MSGFLAG_PROCESSED = UInt32($00000020); // message was processed by recipient
{===============================================================================
TSimpleMessagesClient - class implementation
===============================================================================}
{-------------------------------------------------------------------------------
TSimpleMessagesClient - protected methods
-------------------------------------------------------------------------------}
Function TSimpleMessagesClient.GetClientArrayItemPtr(ClientIndex: Integer): PSMShMemClient;
begin
If CheckClientIndex(ClientIndex) then
{$IFDEF FPCDWM}{$PUSH}W4055{$ENDIF}
Result := PSMShMemClient(Pointer(PtrUInt(fShMemClientArr) + PtrUInt(ClientIndex * SizeOf(TSMShMemClient))))
{$IFDEF FPCDWM}{$POP}{$ENDIF}
else
raise ESMIndexOutOfBounds.CreateFmt('TSimpleMessagesClient.GetClientArrayItemPtr: Index (%d) out of bounds.',[ClientIndex]);
end;
//------------------------------------------------------------------------------
Function TSimpleMessagesClient.GetMessageArrayItemPtr(MessageIndex: TSMMessageIndex): PSMShMemMessage;
begin
If CheckMessageIndex(MessageIndex) then
{$IFDEF FPCDWM}{$PUSH}W4055{$ENDIF}
Result := PSMShMemMessage(Pointer(PtrUInt(fShMemMessageArr) + PtrUInt(MessageIndex * SizeOf(TSMShMemMessage))))
{$IFDEF FPCDWM}{$POP}{$ENDIF}
else
raise ESMIndexOutOfBounds.CreateFmt('TSimpleMessagesClient.GetMessageArrayItemPtr: Index (%d) out of bounds.',[MessageIndex]);
end;
//------------------------------------------------------------------------------
Function TSimpleMessagesClient.GetMessageArrayNextItemPtr(MessageItem: PSMShMemMessage): PSMShMemMessage;
begin
{$IFDEF FPCDWM}{$PUSH}W4055{$ENDIF}
Result := PSMShMemMessage(Pointer(PtrUInt(MessageItem) + PtrUInt(SizeOf(TSMShMemMessage))));
{$IFDEF FPCDWM}{$POP}{$ENDIF}
end;
//------------------------------------------------------------------------------
procedure TSimpleMessagesClient.DecoupleMessage(MessageIndex: TSMMessageIndex);
var
MessageItemPtr: PSMShMemMessage;
begin
If CheckMessageIndex(MessageIndex) then
begin
MessageItemPtr := GetMessageArrayItemPtr(MessageIndex);
If CheckMessageIndex(MessageItemPtr^.Prev) then
GetMessageArrayItemPtr(MessageItemPtr^.Prev)^.Next := MessageItemPtr^.Next;
If CheckMessageIndex(MessageItemPtr^.Next) then
GetMessageArrayItemPtr(MessageItemPtr^.Next)^.Prev := MessageItemPtr^.Prev;
If MessageIndex = fShMemHead^.Messages.FirstFree then
fShMemHead^.Messages.FirstFree := MessageItemPtr^.Next;
If MessageIndex = fShMemHead^.Messages.LastFree then
fShMemHead^.Messages.LastFree := MessageItemPtr^.Prev;
If MessageIndex = fShMemHead^.Messages.FirstUsed then
fShMemHead^.Messages.FirstUsed := MessageItemPtr^.Next;
If MessageIndex = fShMemHead^.Messages.LastUsed then
fShMemHead^.Messages.LastUsed := MessageItemPtr^.Prev;
MessageItemPtr^.Prev := -1;
MessageItemPtr^.Next := -1;
end
else raise ESMIndexOutOfBounds.CreateFmt('TSimpleMessagesClient.DecoupleMessage: Message index (%d) out of bounds.',[MessageIndex]);
end;
//------------------------------------------------------------------------------
Function TSimpleMessagesClient.AddMessage(const Msg: TSMShMemMessage): TSMMessageIndex;
var
MessageItemPtr: PSMShMemMessage;
begin
If CheckMessageIndex(fShMemHead^.Messages.FirstFree) then
begin
Result := fShMemHead^.Messages.FirstFree;
MessageItemPtr := GetMessageArrayItemPtr(Result);
// first move the item from free to used list
DecoupleMessage(MessageItemPtr^.Index);
If not CheckMessageIndex(fShMemHead^.Messages.FirstUsed) then
fShMemHead^.Messages.FirstUsed := MessageItemPtr^.Index;
If CheckMessageIndex(fShMemHead^.Messages.LastUsed) then
GetMessageArrayItemPtr(fShMemHead^.Messages.LastUsed)^.Next := MessageItemPtr^.Index;
MessageItemPtr^.Prev := fShMemHead^.Messages.LastUsed;
MessageItemPtr^.Next := -1;
fShMemHead^.Messages.LastUsed := MessageItemPtr^.Index;
// now copy the data
MessageItemPtr^.Sender := Msg.Sender;
MessageItemPtr^.Recipient := Msg.Recipient;
MessageItemPtr^.Flags := Msg.Flags;
MessageItemPtr^.Timestamp := Msg.Timestamp;
MessageItemPtr^.P1_Result := Msg.P1_Result;
MessageItemPtr^.P2_Counter := Msg.P2_Counter;
MessageItemPtr^.MasterMsg := Msg.MasterMsg;
Inc(fShMemHead^.Messages.Count);
end
else raise ESMOutOfResources.Create('TSimpleMessagesClient.AddMessage: No free message slot.');
end;
//------------------------------------------------------------------------------
procedure TSimpleMessagesClient.RemoveMessage(MessageIndex: TSMMessageIndex);
var
MessageItemPtr: PSMShMemMessage;
begin
If CheckMessageIndex(MessageIndex) then
begin
MessageItemPtr := GetMessageArrayItemPtr(MessageIndex);
// just move the item to the list of free
DecoupleMessage(MessageIndex);
If not CheckMessageIndex(fShMemHead^.Messages.FirstFree) then
fShMemHead^.Messages.FirstFree := MessageIndex;
If CheckMessageIndex(fShMemHead^.Messages.LastFree) then
GetMessageArrayItemPtr(fShMemHead^.Messages.LastFree)^.Next := MessageIndex;
MessageItemPtr^.Prev := fShMemHead^.Messages.LastFree;
MessageItemPtr^.Next := -1;
fShMemHead^.Messages.LastFree := MessageIndex;
Dec(fShMemHead^.Messages.Count);
end
else raise ESMIndexOutOfBounds.CreateFmt('TSimpleMessagesClient.RemoveMessage: Message index (%d) out of bounds.',[MessageIndex]);
end;
//------------------------------------------------------------------------------
procedure TSimpleMessagesClient.ReleaseSentMessage(MessageIndex: TSMMessageIndex; Processed: Boolean; MsgResult: TSMMessageResult);
var
MessageItemPtr: PSMShMemMessage;
begin
If CheckMessageIndex(MessageIndex) then
begin
MessageItemPtr := GetMessageArrayItemPtr(MessageIndex);
If MessageItemPtr^.Flags and SM_MSGFLAG_SENT <> 0 then
begin
If Processed then
begin
MessageItemPtr^.Flags := MessageItemPtr^.Flags or SM_MSGFLAG_PROCESSED;
MessageItemPtr^.P1_Result := MsgResult;
end;
If MessageItemPtr^.Flags and SM_MSGFLAG_MASTER <> 0 then
begin
// broadcasted master message; decrement the counter
MessageItemPtr^.P2_Counter := TSMMEssageParam(Int64(MessageItemPtr^.P2_Counter) - 1);
If Int64(MessageItemPtr^.P2_Counter) <= 0 then
begin
MessageItemPtr^.Flags := MessageItemPtr^.Flags or SM_MSGFLAG_RELEASED;
WakeClient(Integer(MessageItemPtr^.Sender),0);
end;
end
else
begin
// singlecast message
MessageItemPtr^.Flags := MessageItemPtr^.Flags or SM_MSGFLAG_RELEASED;
WakeClient(Integer(MessageItemPtr^.Sender),0);
end;
end;
end
else raise ESMIndexOutOfBounds.CreateFmt('TSimpleMessagesClient.ReleaseMessage: Message index (%d) out of bounds.',[MessageIndex]);
end;
//------------------------------------------------------------------------------
procedure TSimpleMessagesClient.WakeClient(ClientIndex: Integer; SetFlags: UInt32);
var
ClientItemPtr: PSMShMemClient;
{$IFNDEF Windows}
CallResult: cInt;
{$ENDIF}
{$IFDEF Windows}
procedure DuplicateClientSynchronizer;
begin
fClientSyncs[ClientIndex].Assigned := True;
fClientSyncs[ClientIndex].Identifier := ClientItemPtr^.Identifier;
fClientSyncs[ClientIndex].Synchronizer :=
TEvent.DuplicateFromProcessID(ClientItemPtr^.ProcessID,THandle(ClientItemPtr^.Synchronizer));
end;
{$ENDIF}
begin
If CheckClientIndex(ClientIndex) then
begin
ClientItemPtr := GetClientArrayItemPtr(ClientIndex);
{$IFDEF Windows}
If fClientSyncs[ClientIndex].Assigned then
begin
If not IsEqualGUID(fClientSyncs[ClientIndex].Identifier,ClientItemPtr^.Identifier) then
begin
fClientSyncs[ClientIndex].Synchronizer.Free;
DuplicateClientSynchronizer;
end;
end
else DuplicateClientSynchronizer;
{$ENDIF}
// set flags and release the event
ClientItemPtr^.Flags := ClientItemPtr^.Flags or SetFlags;
{$IFDEF Windows}
fClientSyncs[ClientIndex].Synchronizer.SetEventStrict;
{$ELSE}
CallResult := event_auto_unlock(Addr(GetClientArrayItemPtr(ClientIndex)^.Synchronizer));
If CallResult <> 0 then
raise ESMSystemError.CreateFmt('TSimpleMessagesClient.WakeClient: Failed to unlock event (%d)',[CallResult]);
{$ENDIF}
end
else raise ESMIndexOutOfBounds.CreateFmt('TSimpleMessagesClient.WakeClient: Client index (%d) out of bounds.',[ClientIndex]);
end;
//------------------------------------------------------------------------------
procedure TSimpleMessagesClient.ThreadToThreadWakeupCall(ClientIndex: Integer);
type
TObjProc = procedure of object;
var
ClientItemPtr: PSMShMemClient;
MethodToCall: TMethod;
begin
If CheckClientIndex(ClientIndex) then
begin
ClientItemPtr := GetClientArrayItemPtr(ClientIndex);
If ClientItemPtr^.ThreadID = fThreadID then
begin
{$IFDEF FPCDWM}{$PUSH}W4055{$ENDIF}
MethodToCall.Code := Pointer(PtrUInt(ClientItemPtr^.T2TWakeupCode));
MethodToCall.Data := Pointer(PtrUInt(ClientItemPtr^.T2TWakeupData));
{$IFDEF FPCDWM}{$POP}{$ENDIF}
// call the method (unlock data so the called client can safely lock the for itself)
fSharedMemory.Unlock;
try
TObjProc(MethodToCall);
finally
fSharedMemory.Lock;
end;
end;
end
else raise ESMIndexOutOfBounds.CreateFmt('TSimpleMessagesClient.ThreadToThreasWakeupCall: Client index (%d) out of bounds.',[ClientIndex]);
end;
//------------------------------------------------------------------------------
procedure TSimpleMessagesClient.WakeClientsMsgSlots;
var
FreeMsgSlots: Integer;
i: Integer;
begin
// wake clients waiting for free message slot (as many as there is free slots)
If fShMemHead^.Clients.MessageSlotWaitCount > 0 then
begin
FreeMsgSlots := fShMemHead^.MaxMessages - fShMemHead^.Messages.Count;
If FreeMsgSlots > 0 then
For i := LowClientIndex to HighClientIndex do
If (i <> Integer(fClientID)) and fClientMap[i] and
(GetClientArrayItemPtr(i)^.Flags and SM_CLIENTFLAG_MSGSLTWT <> 0) then
begin
WakeClient(i,0);
If FreeMsgSlots > 1 then
Dec(FreeMsgSlots)
else
Break{For i};
end;
end;
end;
//------------------------------------------------------------------------------
procedure TSimpleMessagesClient.WaitMessageSlots(ClientsCount: Boolean);
Function TrueReqCount: Integer;
begin
If ClientsCount then
Result := fShMemHead^.Clients.Count
else
Result := 1;
end;
begin
If fShMemHead^.MaxMessages < (fShMemHead^.Messages.Count + TrueReqCount) then
begin
fShMemClient^.Flags := fShMemClient^.Flags or SM_CLIENTFLAG_MSGSLTWT;
Inc(fShMemHead^.Clients.MessageSlotWaitCount);
try
while fShMemHead^.MaxMessages < (fShMemHead^.Messages.Count + TrueReqCount) do
begin
fSharedMemory.Unlock;
try
{$IFDEF Windows}
fSynchronizer.WaitFor; // infinite wait
{$ELSE}
event_auto_wait(fSynchronizer);
{$ENDIF}
finally
fSharedMemory.Lock;
end;
end;
finally
Dec(fShMemHead^.Clients.MessageSlotWaitCount);
fShMemClient^.Flags := fShMemClient^.Flags and not SM_CLIENTFLAG_MSGSLTWT;
end;
end;
end;
//------------------------------------------------------------------------------
Function TSimpleMessagesClient.SendSinglecast(Recipient: TSMClientID; Param1, Param2: TSMMessageParam): TSMMessageResult;
var
TempMessage: TSMShMemMessage;
MessageItemPtr: PSMShMemMessage;
begin
Result := 0;
TempMessage := ConstructMessage(fClientID,Recipient,SM_MSGFLAG_SENT,Param1,Param2,-1);
// do actual sending only when the recipiend is not this instance
If Recipient <> fClientID then
begin
fSharedMemory.Lock;
try
If fClientMap[Integer(Recipient)] then
begin
// check if there is a place in the message queue, if not, wait for it
WaitMessageSlots(False);
{
Check recipient validity again (it might have been destroyed during
the wait for a free msg slot).
}
If fClientMap[Integer(Recipient)] then
begin
MessageItemPtr := GetMessageArrayItemPtr(AddMessage(TempMessage));
WakeClient(Integer(Recipient),SM_CLIENTFLAG_RECVSMSG);
ThreadToThreadWakeupCall(Integer(Recipient));
// wait for message processing, also process incoming sent messages
while MessageItemPtr^.Flags and SM_MSGFLAG_RELEASED = 0 do
begin
fSharedMemory.Unlock;
try
{$IFDEF Windows}
fSynchronizer.WaitFor; // infinite wait
{$ELSE}
event_auto_wait(fSynchronizer);
{$ENDIF}
If lmrSentMessage in FetchMessages then
DispatchSentMessages;
finally
fSharedMemory.Lock;
end;
end;
// get result and remove the message
If MessageItemPtr^.Flags and SM_MSGFLAG_PROCESSED <> 0 then