Use of optional arguments that aren't present

[LiamPattinson]

The following compiles without issue with gfortran and seg-faults if x is not present:

integer function f(x) result(y)
  integer, intent(in), optional :: x

  y = x + 1

end function f

It should be something like:

integer function f(x) result(y)
  integer, intent(in), optional :: x

  if(present(x)) then
    y = x + 1
  else
    y = 1  ! default
  end if

end function f

The rule would have to catch instances of optional dummy arguments appearing outside of if statements containing present.

It could be tricky to catch every possibility without false positives, as the following works just fine:

  integer function f(x) result(y)
    integer, value, optional :: x

    if(.not. present(x)) x = 0
    y = x + 1

  end function f

It would also need to ensure the condition in the if statement can only be true if present(x) is true, as this also compiles just fine and seg-faults at run time:

integer function f(x) result(y)
  integer, intent(in), optional :: x

  if (present(x) .or. .true.) then
    y = x + 1
  else
    y = 1
  end if

end function f

[ZedThree]

This is another one that's quite tricky, because the code might just be passing the argument off to another one with an optional argument:

subroutine foo(x)
  integer, intent(in), optional :: x
  call bar(1, x)
end subroutine foo

subroutine bar(a, b)
  integer, intent(in), optional :: a, b
end subroutine bar

The trick with value is neat, I'm not sure I've seen that before!

[ZedThree]

The trick with value is actually a gfortran bug, and not something to actually be used

[LiamPattinson]

🙄 And here I thought I'd found a nice workaround to the usual method of:

if (present(x)) then
  x_but_not_optional = x
else
  x_but_not_optional = 0
end if

I always found this to be really clunky.

[ZedThree]

F23 introduces ternaries, so you'll be able to have:

x_but_not_optional = present(x) ? x : 0

No compilers actually support this yet, of course.

I'm also disappointed they didn't go for Python style:

x_but_not_optional = x if present(x) else 0