documentation.gradle

import org.apache.tools.ant.filters.ReplaceTokens

def ramlToCopy = copySpec {
    from('src/main/resources') {
        include 'api-definition.yaml'
        into 'static/cce/docs'
        rename { 'api-definition.raml' }
        filter(ReplaceTokens, tokens: [
                baseUrl: "http://localhost",
                version: version])
        filter{
            line -> line.replaceAll("\"schemas(.*).json\"","\"#/schemas\$1\"")
        }
    }
    from('src/main/resources') {
        include 'api-definition.yaml'
        rename { 'api-definition-raml.yaml' }
        filter(ReplaceTokens, tokens: [
                baseUrl: "http://localhost",
                version: version])
    }
    from('src/main/resources/schemas') {
        include '*.json'
        into 'schemas'
    }
    // those files are needed by Api Console
    from('src/main/resources/schemas') {
        include '*.json'
        into 'static/cce/docs/schemas'
    }
    from('src/main/resources/schemas/fhir') {
        include '*.json'
        into 'static/cce/docs/schemas/fhir'
    }
    // those files are needed by IT
    from('src/main/resources/schemas/fhir') {
        include '*.json'
        into 'schemas/fhir'
        rename '([A-Z][a-z]+).schema.json', '$1'
    }
}

def ramlHtmlToCopy = copySpec {
    from 'src/main/resources'
    include 'api-definition.html'
}

task copyRamlToBuild(type:Copy) {
    with ramlToCopy
    into 'build/resources/main'
}

// Generate static (offline) documentation
task ramlToHtml(type: Exec) {
    description = 'Convert RAML to HTML document'
    commandLine 'npm', 'run', 'runApiHtmlConverter'
}
ramlToHtml.dependsOn(npm_install, copyRamlToBuild)

task copyRamlHtmlToBuild(type:Copy) {
    with ramlHtmlToCopy
    into 'build/resources/main'
}

copyRamlHtmlToBuild.dependsOn ramlToHtml