diff --git a/nixos/modules/module-list.nix b/nixos/modules/module-list.nix
index 91ecee0ef265c..890b0dfa043e8 100644
--- a/nixos/modules/module-list.nix
+++ b/nixos/modules/module-list.nix
@@ -896,6 +896,7 @@
   ./services/monitoring/fusion-inventory.nix
   ./services/monitoring/gatus.nix
   ./services/monitoring/glances.nix
+  ./services/monitoring/glpi-agent.nix
   ./services/monitoring/goss.nix
   ./services/monitoring/grafana-agent.nix
   ./services/monitoring/grafana-image-renderer.nix
diff --git a/nixos/modules/services/monitoring/glpi-agent.nix b/nixos/modules/services/monitoring/glpi-agent.nix
new file mode 100644
index 0000000000000..a5a84171395e7
--- /dev/null
+++ b/nixos/modules/services/monitoring/glpi-agent.nix
@@ -0,0 +1,86 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  cfg = config.services.glpiAgent;
+
+  settingsType =
+    with lib.types;
+    attrsOf (oneOf [
+      bool
+      int
+      str
+      (listOf str)
+    ]);
+
+  formatValue =
+    v:
+    if lib.isBool v then
+      if v then "1" else "0"
+    else if lib.isList v then
+      lib.concatStringsSep "," v
+    else
+      toString v;
+
+  configContent = lib.concatStringsSep "\n" (
+    lib.mapAttrsToList (k: v: "${k} = ${formatValue v}") cfg.settings
+  );
+
+  configFile = pkgs.writeText "agent.cfg" configContent;
+
+in
+{
+  options = {
+    services.glpiAgent = {
+      enable = lib.mkEnableOption "GLPI Agent";
+
+      package = lib.mkPackageOption pkgs "glpi-agent" { };
+
+      settings = lib.mkOption {
+        type = settingsType;
+        default = { };
+        description = ''
+          GLPI Agent configuration options.
+          See https://glpi-agent.readthedocs.io/en/latest/configuration.html for all available options.
+
+          The 'server' option is mandatory and must point to your GLPI server.
+        '';
+        example = lib.literalExpression ''
+          {
+            server = [ "https://glpi.example.com/inventory" ];
+            delaytime = 3600;
+            tag = "production";
+            logger = [ "stderr" "file" ];
+            debug = 1;
+            "no-category" = [ "printer" "software" ];
+          }
+        '';
+      };
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    assertions = [
+      {
+        assertion = cfg.settings ? server;
+        message = "GLPI Agent requires a server to be configured in settings.server";
+      }
+    ];
+
+    systemd.services.glpi-agent = {
+      description = "GLPI Agent";
+      wantedBy = [ "multi-user.target" ];
+      after = [ "network.target" ];
+
+      serviceConfig = {
+        ExecStart = "${lib.getExe cfg.package} --conf-file ${configFile} --vardir /var/lib/glpi-agent --daemon --no-fork";
+        Restart = "on-failure";
+        StateDirectory = "glpi-agent";
+      };
+    };
+  };
+}