From ced6f693ed47591fe7a8257178a720232e20e2b5 Mon Sep 17 00:00:00 2001
From: x123 <x123@users.noreply.github.com>
Date: Sat, 18 Jan 2025 19:58:33 +0100
Subject: [PATCH] crusader: init at 0.3.2

---
 pkgs/by-name/cr/crusader/package.nix | 65 ++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 pkgs/by-name/cr/crusader/package.nix

diff --git a/pkgs/by-name/cr/crusader/package.nix b/pkgs/by-name/cr/crusader/package.nix
new file mode 100644
index 00000000000000..51160af2921341
--- /dev/null
+++ b/pkgs/by-name/cr/crusader/package.nix
@@ -0,0 +1,65 @@
+{
+  autoPatchelfHook,
+  lib,
+  libgcc,
+  libGL,
+  fetchFromGitHub,
+  fontconfig,
+  pkg-config,
+  rustPlatform,
+  stdenv,
+  libxkbcommon,
+  xorg,
+}:
+rustPlatform.buildRustPackage rec {
+  pname = "crusader";
+  version = "0.3.2";
+
+  src = fetchFromGitHub {
+    owner = "Zoxc";
+    repo = "crusader";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-M5zMOOYDS91p0EuDSlQ3K6eiVQpbX6953q+cXBMix2s=";
+  };
+
+  sourceRoot = "${src.name}/src";
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit
+      pname
+      version
+      src
+      sourceRoot
+      ;
+    hash = "sha256-f0TWiRX203/gNsa9UEr/1Bv+kUxLAK/Zlw+S693xZlE=";
+  };
+
+  # autoPatchelfHook required on linux for crusader-gui
+  nativeBuildInputs = [
+    pkg-config
+  ] ++ lib.optionals (!stdenv.isDarwin) [ autoPatchelfHook ];
+
+  buildInputs = [
+    fontconfig
+    libgcc
+    libxkbcommon
+    xorg.libX11
+    xorg.libXcursor
+    xorg.libXi
+  ];
+
+  # required for crusader-gui
+  runtimeDependencies = [
+    libGL
+    libxkbcommon
+  ];
+
+  meta = {
+    description = "Network throughput and latency tester";
+    homepage = "https://github.com/Zoxc/crusader";
+    changelog = "https://github.com/Zoxc/crusader/blob/v${version}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ x123 ];
+    platforms = lib.platforms.all;
+  };
+}