forked from mnottoli/ddPCM
-
Notifications
You must be signed in to change notification settings - Fork 2
/
Copy pathpcm_fmm.f90
3339 lines (3283 loc) · 131 KB
/
pcm_fmm.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
module pcm_fmm
implicit none
real(kind=8) :: sqrt_2=0, sqrt_four_pi=0
contains
! Init global constants
subroutine init_globals(pm, pl, vscales, ngrid, w, grid, vgrid)
! Parameters:
! pm: maximum degree of multipole polynomials to compute
! pl: maximum degree of local polynomials to compute
! vscales: values of scaling factors for spherical harmonics
! ngrid: number of Lebedev grid points
! w: weights of Lebedev grid points
! grid: coordinates of Lebedev grid points on unit sphere
! vgrid: values of spherical harmonics at grid points
integer, intent(in) :: pm, pl, ngrid
real(kind=8), intent(out) :: vscales((pm+pl+1)*(pm+pl+1)), w(ngrid)
real(kind=8), intent(out) :: grid(3, ngrid), vgrid((pl+1)*(pl+1), ngrid)
integer :: i, n, m, indn, indm
real(kind=8) :: c(3), ctheta, stheta, cphi, sphi, vplm((pl+1)*(pl+1))
real(kind=8) :: vcos(pl+1), vsin(pl+1), tmp
sqrt_2 = sqrt(dble(2))
sqrt_four_pi = 4*sqrt(atan(dble(1)))
call scales_real_normal(pl+pm, vscales)
call llgrid(ngrid, w, grid)
do i = 1, ngrid
c = grid(:, i)
ctheta = c(3)
stheta = sqrt(c(1)*c(1) + c(2)*c(2))
if (stheta .ne. 0) then
cphi = c(1) / stheta
sphi = c(2) / stheta
call trgev(cphi, sphi, pl, vcos, vsin)
else
cphi = 1
sphi = 0
vcos = 1
vsin = 0
end if
call polleg(ctheta, stheta, pl, vplm)
do n = 0, pl
indn = n*n + n + 1
vgrid(indn, i) = vscales(indn) * vplm(indn)
do m = 1, n
indm = indn + m
tmp = vscales(indm) * vplm(indm)
vgrid(indn+m, i) = tmp * vcos(1+m)
vgrid(indn-m, i) = tmp * vsin(1+m)
end do
end do
end do
end subroutine init_globals
! Compute cos(mx) and sin(mx) from a given cos(x) and sin(x)
subroutine trgev(c, s, p, vcos, vsin)
! Parameters:
! c: cos(x)
! s: sin(x)
! p: maximum value of m, for which to compute cos(mx) and sin(mx)
! vcos: values of cos(mx) for m from 0 to p
! vsin: values of sin(mx) for m from 0 to p
real(kind=8), intent(in) :: c, s
integer, intent(in) :: p
real(kind=8), intent(out) :: vcos(p+1), vsin(p+1)
integer :: m
vcos(1) = 1
vsin(1) = 0
do m = 2, p+1
vcos(m) = vcos(m-1)*c - vsin(m-1)*s
vsin(m) = vcos(m-1)*s + vsin(m-1)*c
end do
end subroutine trgev
! Compute associated Legendre polynomials P(l,m)(x)
! Uses recurrence formula
! (l-m)P(l,m) = x(2l-1)P(l-1,m) - (l+m-1)P(l-2,m)
! Input x must be in range [-1;1]
! This function is simply copied from ddCOSMO
subroutine polleg(x, y, p, vplm)
! Parameters:
! x: coordinate in interval [-1;1]
! y: sqrt(1-x*2)
! p: maximum degree of polynomials to compute
! vplm: values of associated legendre polynomials P(l,m)(x)
real(kind=8), intent(in) :: x, y
integer, intent(in) :: p
real(kind=8), intent(out) :: vplm((p+1)*(p+1))
integer :: m, ind, l, ind2
real(kind=8) :: fact, pmm, pmm1, pmmo, pll, fm, fl
fact = 1
pmm = 1
do m = 0, p
ind = (m + 1)*(m + 1)
vplm(ind) = pmm
if (m .eq. p) then
return
end if
fm = dble(m)
pmm1 = x * (2*fm+1) * pmm
ind2 = ind + 2*m + 2
vplm(ind2) = pmm1
pmmo = pmm
do l = m+2, p
fl = dble(l)
pll = x*(2*fl-1)*pmm1 - (fl+fm-1)*pmm
pll = pll / (fl-fm)
ind = l*l + l + 1
vplm(ind+m) = pll
pmm = pmm1
pmm1 = pll
end do
pmm = -pmmo * fact * y
fact = fact + 2
end do
end subroutine polleg
! Compute scaling factors for normalized real spherical harmonics
subroutine scales_real_normal(p, vscales)
! Parameters:
! p: maximum degree of spherical harmonics
! vscales: values of scaling factors
integer, intent(in) :: p
real(kind=8), intent(out) :: vscales((p+1)*(p+1))
real(kind=8) :: tmp
integer :: l, ind, m
do l = 0, p
! m = 0
ind = l*l + l + 1
vscales(ind) = sqrt(dble(2*l+1)) / sqrt_four_pi
tmp = vscales(ind) * sqrt_2
! m != 0
do m = 1, l
tmp = -tmp / sqrt(dble((l-m+1)*(l+m)))
vscales(ind+m) = tmp
end do
end do
end subroutine scales_real_normal
! Compute multipole coefficients for particle of unit charge
! Based on normalized scaled real spherical harmonics of given radius
! This function is not needed for pcm, but it is useful for testing purposes
subroutine fmm_p2m(c, r, p, vscales, m)
! Parameters:
! c: coordinates of charged particle (relative to center of harmonics)
! r: radius of spherical harmonics
! p: maximum degree of multipole basis functions
! vscales: normalization constants for Y_lm
! m: multipole coefficients
real(kind=8), intent(in) :: c(3), r, vscales((p+1)*(p+1))
integer, intent(in) :: p
real(kind=8), intent(out) :: m((p+1)*(p+1))
real(kind=8) :: rho, ctheta, stheta, cphi, sphi, vcos(p+1), vsin(p+1)
real(kind=8) :: vplm((p+1)*(p+1)), t, tmp, rcoef
integer :: n, k, ind
stheta = c(1)*c(1) + c(2)*c(2)
rho = sqrt(c(3)*c(3) + stheta)
if (rho .ne. 0) then
ctheta = c(3) / rho
if (stheta .ne. 0) then
stheta = sqrt(stheta)
cphi = c(1) / stheta
sphi = c(2) / stheta
stheta = stheta / rho
call trgev(cphi, sphi, p, vcos, vsin)
else
cphi = 1
sphi = 0
vcos = 1
vsin = 0
end if
call polleg(ctheta, stheta, p, vplm)
! Now build harmonics to fill multipole coefficients
rcoef = rho / r
t = 1
do n = 0, p
ind = n*n + n + 1
m(ind) = t * vscales(ind) * vplm(ind)
do k = 1, n
tmp = t * vscales(ind+k) * vplm(ind+k)
m(ind+k) = tmp * vcos(k+1)
m(ind-k) = tmp * vsin(k+1)
end do
t = t * rcoef
end do
else
m(1) = 1
m(2:) = 0
end if
end subroutine fmm_p2m
! Compute potential, induced by multipole spherical harmonics
! Based on normalized scaled real spherical harmonics of given radius
subroutine fmm_m2p(c, r, p, vscales, m, v)
! Parameters:
! c: relative distance from center of harmonics to point of potential
! r: radius of spherical harmonics
! p: maximum degree of multipole basis functions
! vscales: normalization constants for Y_lm
! m: multipole expansion at origin
! v: value of induced potential
real(kind=8), intent(in) :: c(3), r, vscales((p+1)*(p+1)), m((p+1)*(p+1))
integer, intent(in) :: p
real(kind=8), intent(out) :: v
real(kind=8) :: tmp, tmp1, tmp2
real(kind=8) :: rho, t, ctheta, stheta, cphi, sphi, vcos(p+1), vsin(p+1)
real(kind=8) :: vplm((p+1)*(p+1)), rcoef
integer :: n, k, ind
t = 1 / r
stheta = c(1)*c(1) + c(2)*c(2)
rho = sqrt(c(3)*c(3) + stheta)
v = 0
if (rho .eq. 0) then
return
end if
! rho is always > 0
ctheta = c(3) / rho
if (stheta .ne. 0) then
stheta = sqrt(stheta)
cphi = c(1) / stheta
sphi = c(2) / stheta
stheta = stheta / rho
call trgev(cphi, sphi, p, vcos, vsin)
else
cphi = 1
sphi = 0
vcos = 1
vsin = 0
end if
call polleg(ctheta, stheta, p, vplm)
rcoef = r / rho
do n = 0, p
t = t * rcoef
ind = n*n + n + 1
! k = 0
tmp = m(ind) * vplm(ind) * vscales(ind)
! k != 0
do k = 1, n
tmp1 = vplm(ind+k) * vscales(ind+k)
tmp2 = m(ind+k)*vcos(k+1) + m(ind-k)*vsin(k+1)
tmp = tmp + tmp1*tmp2
end do
v = v + t*tmp/vscales(ind)**2
end do
end subroutine fmm_m2p
! M2M baseline translation (p^4 operations)
! Baseline in terms of operation count: p^4
subroutine fmm_m2m_baseline(c, src_r, dst_r, p, vscales, src_m, dst_m)
! Parameters:
! c: radius-vector from new to old centers of harmonics
! src_r: radius of old harmonics
! dst_r: radius of new harmonics
! p: maximum degree of spherical harmonics
! vscales: normalization constants for Y_lm
! src_m: expansion in old harmonics
! dst_m: expansion in new harmonics
real(kind=8), intent(in) :: c(3), src_r, dst_r, vscales((p+1)*(p+1))
real(kind=8), intent(in) :: src_m((p+1)*(p+1))
integer, intent(in) :: p
real(kind=8), intent(inout) :: dst_m((p+1)*(p+1))
real(kind=8) :: r, r1, r2, ctheta, stheta, cphi, sphi, vcos(p+1), vsin(p+1)
real(kind=8) :: vplm((p+1)*(p+1)), fact(2*p+1), tmpk1, tmpk2, tmpk3, tmp1
real(kind=8) :: tmp2, pow_r1(p+1), pow_r2(p+1)
integer :: j, k, n, m, indj, indm, indn, indjn
stheta = c(1)*c(1) + c(2)*c(2)
r = sqrt(c(3)*c(3) + stheta)
if (r .ne. 0) then
ctheta = c(3) / r
if (stheta .ne. 0) then
stheta = sqrt(stheta)
cphi = c(1) / stheta
sphi = c(2) / stheta
stheta = stheta / r
call trgev(cphi, sphi, p, vcos, vsin)
else
cphi = 1
sphi = 0
vcos = 1
vsin = 0
end if
call polleg(ctheta, stheta, p, vplm)
r1 = src_r / dst_r
r2 = r / dst_r
pow_r1(1) = 1
pow_r2(1) = 1
do j = 2, p+1
pow_r1(j) = pow_r1(j-1) * r1
pow_r2(j) = pow_r2(j-1) * r2
end do
! Fill square roots of factorials
fact(1) = 1
do j = 2, 2*p+1
fact(j) = sqrt(dble(j-1)) * fact(j-1)
end do
do j = 0, p
indj = j*j + j + 1
do k = 0, j
tmp1 = vscales(indj) * fact(j-k+1) * fact(j+k+1)
if (k .ne. 0) then
tmp1 = tmp1 * sqrt_2
end if
do n = 0, j
indn = n*n + n + 1
indjn = (j-n)**2 + (j-n) + 1
tmp2 = tmp1 * pow_r1(j-n+1) * pow_r2(n+1) / &
& vscales(indjn) / vscales(indn)
do m = max(k+n-j, -n), min(k+j-n, n)
indm = indn + abs(m)
cphi = vcos(1+abs(m))
sphi = vsin(1+abs(m))
tmpk1 = tmp2 / fact(n-m+1) / fact(n+m+1) / &
& fact(j-n-k+m+1) / fact(j-n+k-m+1) * &
& vplm(indm) * vscales(indm)
if (mod(abs(k-abs(m)-abs(k-m)), 4) .eq. 2) then
tmpk1 = -tmpk1
end if
tmpk2 = src_m(indjn+abs(k-m)) * cphi
if ((m .ge. 0) .and. (m .le. k)) then
sphi = -sphi
end if
tmpk3 = -src_m(indjn+abs(k-m)) * sphi
if (m .ne. 0) then
tmpk1 = tmpk1 / sqrt_2
end if
if (m .ne. k) then
tmpk1 = tmpk1 / sqrt_2
tmpk2 = tmpk2 + src_m(indjn-abs(k-m))*sphi
tmpk3 = tmpk3 + src_m(indjn-abs(k-m))*cphi
end if
if (m .gt. k) then
tmpk3 = -tmpk3
end if
dst_m(indj+k) = dst_m(indj+k) + tmpk1*tmpk2
if (k .ne. 0) then
dst_m(indj-k) = dst_m(indj-k) + tmpk1*tmpk3
end if
end do
end do
end do
end do
else
r1 = src_r / dst_r
tmpk1 = 1
do j = 0, p
indj = j*j + j + 1
do k = indj-j, indj+j
dst_m(k) = dst_m(k) + src_m(k)*tmpk1
end do
tmpk1 = tmpk1 * r1
end do
end if
end subroutine fmm_m2m_baseline
! Compute potential, induced by local spherical harmonics
! Based on normalized scaled real spherical harmonics of given radius
subroutine fmm_l2p(c, r, p, vscales, l, v)
! Parameters:
! c: relative distance from center of harmonics to point of potential
! r: radius of spherical harmonics
! p: maximum degree of local basis functions
! vscales: normalization constants for Y_lm
! l: local expansion at origin
! v: value of induced potential
real(kind=8), intent(in) :: c(3), r, vscales((p+1)*(p+1)), l((p+1)*(p+1))
integer, intent(in) :: p
real(kind=8), intent(out) :: v
real(kind=8) :: tmp, tmp1, tmp2
real(kind=8) :: rho, t, ctheta, stheta, cphi, sphi, vcos(p+1), vsin(p+1)
real(kind=8) :: vplm((p+1)*(p+1)), rcoef
integer :: n, k, ind
t = 1 / r
stheta = c(1)*c(1) + c(2)*c(2)
rho = sqrt(c(3)*c(3) + stheta)
if (rho .eq. 0) then
! Only first term
v = t * l(1) / vscales(1)
return
end if
v = 0
ctheta = c(3) / rho
if (stheta .ne. 0) then
stheta = sqrt(stheta)
cphi = c(1) / stheta
sphi = c(2) / stheta
stheta = stheta / rho
call trgev(cphi, sphi, p, vcos, vsin)
else
cphi = 1
sphi = 0
vcos = 1
vsin = 0
end if
call polleg(ctheta, stheta, p, vplm)
rcoef = rho / r
do n = 0, p
ind = n*n + n + 1
! k = 0
tmp = l(ind) * vplm(ind) * vscales(ind)
! k != 0
do k = 1, n
tmp1 = vplm(ind+k) * vscales(ind+k)
tmp2 = l(ind+k)*vcos(k+1) + l(ind-k)*vsin(k+1)
tmp = tmp + tmp1*tmp2
end do
v = v + t*tmp/vscales(ind)**2
t = t * rcoef
end do
end subroutine fmm_l2p
! Compute local expansion by given multipole expansion
! Baseline in terms of operation count: p^4
subroutine fmm_m2l_baseline(c, src_r, dst_r, pm, pl, vscales, src_m, dst_l)
! Parameters:
! c: radius-vector from new (local) to old (multipole) centers of harmonics
! src_r: radius of old (multipole) harmonics
! dst_r: radius of new (local) harmonics
! pm: maximum degree of multipole spherical harmonics
! pl: maximum degree of local spherical harmonics
! vscales: normalization constants for Y_lm (of degree up to pl+pm)
! src_m: expansion in old (multipole) harmonics
! dst_l: expansion in new (local) harmonics
real(kind=8), intent(in) :: c(3), src_r, dst_r
real(kind=8), intent(in) :: vscales((pm+pl+1)*(pm+pl+1))
real(kind=8), intent(in) :: src_m((pm+1)*(pm+1))
integer, intent(in) :: pm, pl
real(kind=8), intent(inout) :: dst_l((pl+1)*(pl+1))
real(kind=8) :: r, r1, r2, ctheta, stheta, cphi, sphi
real(kind=8) :: vcos(pm+pl+1), vsin(pm+pl+1)
real(kind=8) :: vplm((pm+pl+1)*(pm+pl+1)), fact(2*(pm+pl)+1), tmpk1, tmpk2
real(kind=8) :: tmpk3, tmp1, tmp2, pow_r1(pm+1), pow_r2(pl+1)
integer :: j, k, n, m, indj, indmk, indn, indjn
stheta = c(1)*c(1) + c(2)*c(2)
r = sqrt(c(3)*c(3) + stheta)
! r cannot be zero, as input sphere (multipole) must not intersect with
! output sphere (local)
if (r .eq. 0) then
return
end if
ctheta = c(3) / r
if (stheta .ne. 0) then
stheta = sqrt(stheta)
cphi = c(1) / stheta
sphi = c(2) / stheta
stheta = stheta / r
call trgev(cphi, sphi, pm+pl, vcos, vsin)
else
cphi = 1
sphi = 0
vcos = 1
vsin = 0
end if
call polleg(ctheta, stheta, pm+pl, vplm)
r1 = src_r / r
r2 = dst_r / r
pow_r1(1) = 1
pow_r2(1) = r2
do j = 2, pm+1
pow_r1(j) = pow_r1(j-1) * r1
end do
do j = 2, pl+1
pow_r2(j) = pow_r2(j-1) * r2
end do
! Fill square roots of factorials
fact(1) = 1
do j = 2, 2*(pm+pl)+1
fact(j) = sqrt(dble(j-1)) * fact(j-1)
end do
do j = 0, pl
indj = j*j + j + 1
do k = 0, j
tmp1 = vscales(indj) * pow_r2(j+1) / fact(j-k+1) / fact(j+k+1)
if (k .ne. 0) then
tmp1 = tmp1 * sqrt_2
end if
do n = 0, pm
indn = n*n + n + 1
indjn = (j+n)**2 + (j+n) + 1
tmp2 = tmp1 * pow_r1(n+1) / vscales(indjn) / vscales(indn)
if (mod(n, 2) .eq. 1) then
tmp2 = -tmp2
end if
do m = -n, n
indmk = indjn + abs(m-k)
cphi = vcos(1+abs(m-k))
sphi = vsin(1+abs(m-k))
tmpk1 = tmp2 / fact(n-m+1) / fact(n+m+1) * &
& fact(j+n-m+k+1) * fact(j+n+m-k+1) * vplm(indmk) * &
& vscales(indmk)
if (mod(abs(k+abs(m)-abs(k-m)), 4) .eq. 2) then
tmpk1 = -tmpk1
end if
tmpk2 = src_m(indn+abs(m)) * cphi
if ((m .ge. 0) .and. (m .le. k)) then
sphi = -sphi
end if
tmpk3 = -src_m(indn+abs(m)) * sphi
if (m .ne. k) then
tmpk1 = tmpk1 / sqrt_2
end if
if (m .ne. 0) then
tmpk1 = tmpk1 / sqrt_2
tmpk2 = tmpk2 + src_m(indn-abs(m))*sphi
tmpk3 = tmpk3 + src_m(indn-abs(m))*cphi
end if
if (m .lt. 0) then
tmpk3 = -tmpk3
end if
dst_l(indj+k) = dst_l(indj+k) + tmpk1*tmpk2
if (k .ne. 0) then
dst_l(indj-k) = dst_l(indj-k) + tmpk1*tmpk3
end if
end do
end do
end do
end do
end subroutine fmm_m2l_baseline
! Translate local expansion to another sphere
! Baseline in terms of operation count: p^4
subroutine fmm_l2l_baseline(c, src_r, dst_r, p, vscales, src_l, dst_l)
! Parameters:
! c: radius-vector from new to old centers of harmonics
! src_r: radius of old harmonics
! dst_r: radius of new harmonics
! p: maximum degree of local spherical harmonics
! vscales: normalization constants for Y_lm (of degree up to p)
! src_l: expansion in old harmonics
! dst_l: expansion in new harmonics
real(kind=8), intent(in) :: c(3), src_r, dst_r, vscales((p+1)*(p+1))
real(kind=8), intent(in) :: src_l((p+1)*(p+1))
integer, intent(in) :: p
real(kind=8), intent(inout) :: dst_l((p+1)*(p+1))
real(kind=8) :: r, r1, r2, ctheta, stheta, cphi, sphi
real(kind=8) :: vcos(p+1), vsin(p+1)
real(kind=8) :: vplm((p+1)*(p+1)), fact(2*p+1), tmpk1, tmpk2, tmpk3
real(kind=8) :: tmp1, tmp2, pow_r1(p+1), pow_r2(p+1)
integer :: j, k, n, m, indj, indmk, indn, indjn
stheta = c(1)*c(1) + c(2)*c(2)
r = sqrt(c(3)*c(3) + stheta)
if (r .ne. 0) then
ctheta = c(3) / r
if (stheta .ne. 0) then
stheta = sqrt(stheta)
cphi = c(1) / stheta
sphi = c(2) / stheta
stheta = stheta / r
call trgev(cphi, sphi, p, vcos, vsin)
else
cphi = 1
sphi = 0
vcos = 1
vsin = 0
end if
call polleg(ctheta, stheta, p, vplm)
r1 = r / src_r
r2 = dst_r / r
pow_r1(1) = r1
pow_r2(1) = r2
do j = 2, p+1
pow_r1(j) = pow_r1(j-1) * r1
pow_r2(j) = pow_r2(j-1) * r2
end do
! Fill square roots of factorials
fact(1) = 1
do j = 2, 2*p+1
fact(j) = sqrt(dble(j-1)) * fact(j-1)
end do
do j = 0, p
indj = j*j + j + 1
do k = 0, j
tmp1 = pow_r2(j+1) / fact(j-k+1) / fact(j+k+1) * vscales(indj)
if (k .ne. 0) then
tmp1 = tmp1 * sqrt_2
end if
do n = j, p
indn = n*n + n + 1
indjn = (n-j)**2 + (n-j) + 1
tmp2 = tmp1 * pow_r1(n+1) / vscales(indjn) / vscales(indn)
if (mod(n+j, 2) .eq. 1) then
tmp2 = -tmp2
end if
do m = k+j-n, k+n-j
indmk = indjn + abs(m-k)
cphi = vcos(1+abs(m-k))
sphi = vsin(1+abs(m-k))
tmpk1 = tmp2 * fact(n-m+1) * fact(n+m+1) / &
& fact(n-j-m+k+1) / fact(n-j+m-k+1) * &
& vplm(indmk) * vscales(indmk)
if (mod(abs(k+abs(m-k)-abs(m)), 4) .eq. 2) then
tmpk1 = -tmpk1
end if
tmpk2 = src_l(indn+abs(m)) * cphi
if ((m .ge. 0) .and. (m .le. k)) then
sphi = -sphi
end if
tmpk3 = -src_l(indn+abs(m)) * sphi
if (m .ne. k) then
tmpk1 = tmpk1 / sqrt_2
end if
if (m .ne. 0) then
tmpk1 = tmpk1 / sqrt_2
tmpk2 = tmpk2 + src_l(indn-abs(m))*sphi
tmpk3 = tmpk3 + src_l(indn-abs(m))*cphi
end if
if (m .lt. 0) then
tmpk3 = -tmpk3
end if
dst_l(indj+k) = dst_l(indj+k) + tmpk1*tmpk2
if (k .ne. 0) then
dst_l(indj-k) = dst_l(indj-k) + tmpk1*tmpk3
end if
end do
end do
end do
end do
else
r1 = dst_r / src_r
tmpk1 = r1
do j = 0, p
indj = j*j + j + 1
do k = indj-j, indj+j
dst_l(k) = dst_l(k) + src_l(k)*tmpk1
end do
tmpk1 = tmpk1 * r1
end do
end if
end subroutine fmm_l2l_baseline
! Optimized version of M2M, translation over OZ axis only
subroutine fmm_m2m_ztranslate(z, src_r, dst_r, p, vscales, src_m, dst_m)
! Parameters:
! z: radius-vector from new to old centers of harmonics (z coordinate only)
! src_r: radius of old harmonics
! dst_r: radius of new harmonics
! p: maximum degree of spherical harmonics
! vscales: normalization constants for Y_lm
! src_m: expansion in old harmonics
! dst_m: expansion in new harmonics
real(kind=8), intent(in) :: z, src_r, dst_r, vscales((p+1)*(p+1))
real(kind=8), intent(in) :: src_m((p+1)*(p+1))
integer, intent(in) :: p
real(kind=8), intent(inout) :: dst_m((p+1)*(p+1))
real(kind=8) :: r1, r2, fact(2*p+1), tmp1, tmp2, pow_r1(p+1), pow_r2(p+1)
integer :: j, k, n, indj, indn, indjn
if (z .ne. 0) then
r1 = src_r / dst_r
r2 = z / dst_r
pow_r1(1) = 1
pow_r2(1) = 1
do j = 2, p+1
pow_r1(j) = pow_r1(j-1) * r1
pow_r2(j) = pow_r2(j-1) * r2
end do
! Fill square roots of factorials
fact(1) = 1
do j = 2, 2*p+1
fact(j) = sqrt(dble(j-1)) * fact(j-1)
end do
do j = 0, p
indj = j*j + j + 1
do k = 0, j
tmp1 = vscales(indj) * fact(j-k+1) * fact(j+k+1)
do n = 0, j-k
indn = n*n + n + 1
indjn = (j-n)**2 + (j-n) + 1
tmp2 = tmp1 * pow_r1(j-n+1) * pow_r2(n+1) / &
& vscales(indjn) / fact(n+1) / fact(n+1) / &
& fact(j-n-k+1) / fact(j-n+k+1)
if (k .eq. 0) then
dst_m(indj) = dst_m(indj) + tmp2*src_m(indjn)
else
dst_m(indj+k) = dst_m(indj+k) + tmp2*src_m(indjn+k)
dst_m(indj-k) = dst_m(indj-k) + tmp2*src_m(indjn-k)
end if
end do
end do
end do
else
r1 = src_r / dst_r
tmp1 = 1
do j = 0, p
indj = j*j + j + 1
do k = indj-j, indj+j
dst_m(k) = dst_m(k) + src_m(k)*tmp1
end do
tmp1 = tmp1 * r1
end do
end if
end subroutine fmm_m2m_ztranslate
! Optimized version of M2L, translation over OZ axis only
subroutine fmm_m2l_ztranslate(z, src_r, dst_r, pm, pl, vscales, src_m, dst_l)
! Parameters:
! z: radius-vector from new to old centers of harmonics (z coordinate only)
! src_r: radius of old (multipole) harmonics
! dst_r: radius of new (local) harmonics
! pm: maximum degree of multipole spherical harmonics
! pl: maximum degree of local spherical harmonics
! vscales: normalization constants for Y_lm (of degree up to pl+pm)
! src_m: expansion in old (multipole) harmonics
! dst_l: expansion in new (local) harmonics
real(kind=8), intent(in) :: z, src_r, dst_r
real(kind=8), intent(in) :: vscales((pm+pl+1)*(pm+pl+1))
real(kind=8), intent(in) :: src_m((pm+1)*(pm+1))
integer, intent(in) :: pm, pl
real(kind=8), intent(inout) :: dst_l((pl+1)*(pl+1))
real(kind=8) :: fact(2*(pm+pl)+1), tmp1, tmp2, pow_r1(pm+1), pow_r2(pl+1)
real(kind=8) :: r1, r2
integer :: j, k, n, indj, indn, indjn
! z cannot be zero, as input sphere (multipole) must not intersect with
! output sphere (local)
if (z .eq. 0) then
return
end if
r1 = src_r / z
r2 = dst_r / z
pow_r1(1) = 1
! This abs(r2) makes it possible to work with negative z to avoid
! unnecessary rotation to positive z
pow_r2(1) = abs(r2)
do j = 2, pm+1
pow_r1(j) = pow_r1(j-1) * r1
end do
do j = 2, pl+1
pow_r2(j) = pow_r2(j-1) * r2
end do
! Fill square roots of factorials
fact(1) = 1
do j = 2, 2*(pm+pl)+1
fact(j) = sqrt(dble(j-1)) * fact(j-1)
end do
do j = 0, pl
indj = j*j + j + 1
do k = 0, j
tmp1 = vscales(indj) * pow_r2(j+1) / fact(j-k+1) / fact(j+k+1)
do n = k, pm
indn = n*n + n + 1
indjn = (j+n)**2 + (j+n) + 1
tmp2 = tmp1 * pow_r1(n+1) / vscales(indn) / fact(n-k+1) / &
& fact(n+k+1) * fact(j+n+1) * fact(j+n+1)
if (mod(n+k, 2) .eq. 1) then
tmp2 = -tmp2
end if
if (k .eq. 0) then
dst_l(indj) = dst_l(indj) + tmp2*src_m(indn)
else
dst_l(indj+k) = dst_l(indj+k) + tmp2*src_m(indn+k)
dst_l(indj-k) = dst_l(indj-k) + tmp2*src_m(indn-k)
end if
end do
end do
end do
end subroutine fmm_m2l_ztranslate
! Optimized version of L2L, translation over OZ axis only
subroutine fmm_l2l_ztranslate(z, src_r, dst_r, p, vscales, src_l, dst_l)
! Parameters:
! z: radius-vector from new to old centers of harmonics (z coordinate only)
! src_r: radius of old harmonics
! dst_r: radius of new harmonics
! p: maximum degree of local spherical harmonics
! vscales: normalization constants for Y_lm (of degree up to p)
! src_l: expansion in old harmonics
! dst_l: expansion in new harmonics
real(kind=8), intent(in) :: z, src_r, dst_r, vscales((p+1)*(p+1))
real(kind=8), intent(in) :: src_l((p+1)*(p+1))
integer, intent(in) :: p
real(kind=8), intent(inout) :: dst_l((p+1)*(p+1))
real(kind=8) :: r1, r2, fact(2*p+1)
real(kind=8) :: tmp1, tmp2, pow_r1(p+1), pow_r2(p+1)
integer :: j, k, n, indj, indn, indjn
if (z .ne. 0) then
r1 = z / src_r
r2 = dst_r / z
pow_r1(1) = r1
pow_r2(1) = r2
do j = 2, p+1
pow_r1(j) = pow_r1(j-1) * r1
pow_r2(j) = pow_r2(j-1) * r2
end do
! Fill square roots of factorials
fact(1) = 1
do j = 2, 2*p+1
fact(j) = sqrt(dble(j-1)) * fact(j-1)
end do
do j = 0, p
indj = j*j + j + 1
do k = 0, j
tmp1 = pow_r2(j+1) / fact(j-k+1) / fact(j+k+1) * vscales(indj)
do n = j, p
indn = n*n + n + 1
indjn = (n-j)**2 + (n-j) + 1
tmp2 = tmp1 * pow_r1(n+1) / vscales(indn) * fact(n-k+1) * &
& fact(n+k+1) / fact(n-j+1) / fact(n-j+1)
if (mod(n+j, 2) .eq. 1) then
tmp2 = -tmp2
end if
if (k .eq. 0) then
dst_l(indj) = dst_l(indj) + tmp2*src_l(indn)
else
dst_l(indj+k) = dst_l(indj+k) + tmp2*src_l(indn+k)
dst_l(indj-k) = dst_l(indj-k) + tmp2*src_l(indn-k)
end if
end do
end do
end do
else
r1 = dst_r / src_r
tmp1 = r1
do j = 0, p
indj = j*j + j + 1
do k = indj-j, indj+j
dst_l(k) = dst_l(k) + src_l(k)*tmp1
end do
tmp1 = tmp1 * r1
end do
end if
end subroutine fmm_l2l_ztranslate
! Auxiliary routine to transform (rotate, reflect) spherical harmonics
! Factor u_lnm (lower case) from the paper:
! ``Rotation Matrices for Real Spherical Harmonics. Direct Determination by
! Recursion'', J.Ivanic and K.Ruedenberg, J. Phys. Chem. 1996, 100, 6342-6347
! This routine serves only for debugging purposes, as there are much faster
! implementations
subroutine fmm_sph_transform_get_u(l, n, m, c)
! Parameters:
! l: order of spherical harmonics
! n: index of initial spherical harmonic
! m: index of output (rotated or reflected) spherical harmonic
! c: value of factor u_lnm (lower case)
integer, intent(in) :: l, n, m
real(kind=8), intent(out) :: c
c = l*l - n*n
if (abs(m) .eq. l) then
c = c / (2*l) / (2*l-1)
else
c = c / (l*l - m*m)
end if
c = sqrt(c)
end subroutine fmm_sph_transform_get_u
! Auxiliary routine to transform (rotate, reflect) spherical harmonics
! Factor v_lnm (lower case) from the paper:
! ``Rotation Matrices for Real Spherical Harmonics. Direct Determination by
! Recursion'', J.Ivanic and K.Ruedenberg, J. Phys. Chem. 1996, 100, 6342-6347
! This routine serves only for debugging purposes, as there are much faster
! implementations
subroutine fmm_sph_transform_get_v(l, n, m, c)
! Parameters:
! l: order of spherical harmonics
! n: index of initial spherical harmonic
! m: index of output (rotated or reflected) spherical harmonic
! c: value of factor v_lnm (lower case)
integer, intent(in) :: l, n, m
real(kind=8), intent(out) :: c
integer :: k
c = 1
if (abs(m) .eq. l) then
c = c / (2*l) / (2*l-1)
else
c = c / (l*l - m*m)
end if
if (n .eq. 0) then
c = c * 2 * l * (l-1)
c = -sqrt(c) / 2
else
k = abs(n)
c = c * (l+k-1) * (l+k)
c = sqrt(c) / 2
end if
end subroutine fmm_sph_transform_get_v
! Auxiliary routine to transform (rotate, reflect) spherical harmonics
! Factor w_lnm (lower case) from the paper:
! ``Rotation Matrices for Real Spherical Harmonics. Direct Determination by
! Recursion'', J.Ivanic and K.Ruedenberg, J. Phys. Chem. 1996, 100, 6342-6347
! This routine serves only for debugging purposes, as there are much faster
! implementations
subroutine fmm_sph_transform_get_w(l, n, m, c)
! Parameters:
! l: order of spherical harmonics
! n: index of initial spherical harmonic
! m: index of output (rotated or reflected) spherical harmonic
! c: value of factor w_lnm (lower case)
integer, intent(in) :: l, n, m
real(kind=8), intent(out) :: c
integer :: k
if (n .eq. 0) then
c = 0
return
end if
c = 1
if (abs(m) .eq. l) then
c = c / (2*l) / (2*l-1)
else
c = c / (l*l - m*m)
end if
k = abs(n)
c = c * (l-k-1) * (l-k)
c = -sqrt(c) / 2
end subroutine fmm_sph_transform_get_w
! Auxiliary routine to transform (rotate, reflect) spherical harmonics
! Factor P_linm from the paper:
! ``Rotation Matrices for Real Spherical Harmonics. Direct Determination by
! Recursion'', J.Ivanic and K.Ruedenberg, J. Phys. Chem. 1996, 100, 6342-6347
! This routine serves only for debugging purposes, as there are much faster
! implementations
subroutine fmm_sph_transform_get_p(l, i, n, m, r, r_prev, c)
! Parameters:
! l: order of spherical harmonics
! i: -1, 0 or 1
! n: index of initial spherical harmonic
! m: index of output (rotated or reflected) spherical harmonic
! r: transformation matrix from initial axes to rotated axes
! r_prev: transformation matrix for all spherical harmonics of order l-1
! c: value of factor P_linm
integer, intent(in) :: l, i, n, m
real(kind=8), intent(in) :: r(-1:1, -1:1), r_prev(1-l:l-1, 1-l:l-1)
real(kind=8), intent(out) :: c
if (m .eq. l) then
c = r(i, 1)*r_prev(n, l-1) - r(i, -1)*r_prev(n, 1-l)
else if (m .eq. -l) then
c = r(i, 1)*r_prev(n, 1-l) + r(i, -1)*r_prev(n, l-1)
else
c = r(i, 0) * r_prev(n, m)
end if
end subroutine fmm_sph_transform_get_p
! Auxiliary routine to transform (rotate, reflect) spherical harmonics
! Factor u_lnm * U_lnm from the paper:
! ``Rotation Matrices for Real Spherical Harmonics. Direct Determination by
! Recursion'', J.Ivanic and K.Ruedenberg, J. Phys. Chem. 1996, 100, 6342-6347
! This routine serves only for debugging purposes, as there are much faster
! implementations
subroutine fmm_sph_transform_get_uu(l, n, m, r, r_prev, c)
! Parameters:
! l: order of spherical harmonics
! n: index of initial spherical harmonic
! m: index of output (rotated or reflected) spherical harmonic
! r: transformation matrix from initial axes to rotated axes
! r_prev: transformation matrix for all spherical harmonics of order l-1
! c: value of factor u_lnm * U_lnm
integer, intent(in) :: l, n, m
real(kind=8), intent(in) :: r(-1:1, -1:1), r_prev(1-l:l-1, 1-l:l-1)
real(kind=8), intent(out) :: c
real(kind=8) :: c1
call fmm_sph_transform_get_u(l, n, m, c)
if (c .ne. 0) then
call fmm_sph_transform_get_p(l, 0, n, m, r, r_prev, c1)
c = c * c1
end if
end subroutine fmm_sph_transform_get_uu
! Auxiliary routine to transform (rotate, reflect) spherical harmonics
! Factor v_lnm * V_lnm from the paper:
! ``Rotation Matrices for Real Spherical Harmonics. Direct Determination by
! Recursion'', J.Ivanic and K.Ruedenberg, J. Phys. Chem. 1996, 100, 6342-6347
! This routine serves only for debugging purposes, as there are much faster
! implementations
subroutine fmm_sph_transform_get_vv(l, n, m, r, r_prev, c)
! Parameters:
! l: order of spherical harmonics
! n: index of initial spherical harmonic
! m: index of output (rotated or reflected) spherical harmonic
! r: transformation matrix from initial axes to rotated axes
! r_prev: transformation matrix for all spherical harmonics of order l-1
! c: value of factor v_lnm * V_lnm
integer, intent(in) :: l, n, m
real(kind=8), intent(in) :: r(-1:1, -1:1), r_prev(1-l:l-1, 1-l:l-1)
real(kind=8), intent(out) :: c
real(kind=8) :: c1, c2
call fmm_sph_transform_get_v(l, n, m, c)
if (c .eq. 0) then
return
end if
if (n .gt. 1) then
call fmm_sph_transform_get_p(l, 1, n-1, m, r, r_prev, c1)
call fmm_sph_transform_get_p(l, -1, 1-n, m, r, r_prev, c2)
c = c * (c1-c2)
else if (n .eq. 1) then
call fmm_sph_transform_get_p(l, 1, 0, m, r, r_prev, c1)
c = sqrt_2 * c * c1
else if (n .eq. 0) then
call fmm_sph_transform_get_p(l, 1, 1, m, r, r_prev, c1)
call fmm_sph_transform_get_p(l, -1, -1, m, r, r_prev, c2)
c = c * (c1+c2)
else if (n .eq. -1) then
call fmm_sph_transform_get_p(l, -1, 0, m, r, r_prev, c1)
c = sqrt_2 * c * c1
else
call fmm_sph_transform_get_p(l, 1, n+1, m, r, r_prev, c1)
call fmm_sph_transform_get_p(l, -1, -1-n, m, r, r_prev, c2)
c = c * (c1+c2)
end if
end subroutine fmm_sph_transform_get_vv
! Auxiliary routine to transform (rotate, reflect) spherical harmonics
! Factor w_lnm * W_lnm from the paper: