build.gradle

// Configure Auto Relocation
import com.github.jengelman.gradle.plugins.shadow.tasks.ConfigureShadowRelocation

// We use this to replace version in plugin.yml
// import org.apache.tools.ant.filters.ReplaceTokens

plugins {
    id 'java'
    id 'application'
    id 'kr.entree.spigradle' version '2.4.3'
    id "io.freefair.lombok" version "6.0.0-m2"
    id 'com.github.johnrengelman.shadow' version '7.1.2'
}

import groovy.json.JsonSlurper
def packageSlurper = new JsonSlurper()
def packageJson = packageSlurper.parse file('package.json')

group = 'me.magnum' // Put your groupId here
version = packageJson.version
archivesBaseName = 'BreedablePets' // Put your artifactId here
mainClassName = 'me.magnum.Breedable'
targetCompatibility = 1.8
sourceCompatibility = 1.8

// See https://github.com/EntryPointKR/Spigradle#repositories for repository shortcodes
repositories {
//    mavenLocal()
    mavenCentral()
    paper()
    enderZone()
    maven { url = "https://repo.aikar.co/content/groups/aikar/" }
    jitpack() // For vault
}

dependencies {
    compileOnly spigot('1.15.2')
    implementation 'fr.mrmicky:FastParticles:2.0.0'
    implementation 'com.github.Magnum97:LightningStorage:3.2.2'
//    implementation  'com.github.JavaFactoryDev:LightningStorage:3.1.1-SNAPSHOT'
    implementation "co.aikar:acf-bukkit:0.5.1-SNAPSHOT"
//    implementation 'com.github.kangarko:Foundation:5.3.8@jar' // Kangerko's Foundation library

}
defaultTasks 'clean', 'shadowJar'
compileJava {
    options.compilerArgs += ["-parameters"]
    options.fork = true
    options.forkOptions.executable = 'javac'
}
task relocateShadowJar(type: ConfigureShadowRelocation) {
    target = tasks.shadowJar
    prefix = "shadow" // Default value is "shadow"

}
tasks.shadowJar.dependsOn tasks.relocateShadowJar
shadowJar {
    classifier = null // remove -all from end of jar
}
spigot {
    authors = ['Magnum1997']
//    depends = ['ProtocolLib']
    apiVersion = '1.15'
    load = STARTUP
    commands {
        breedablepets {
            aliases = ['bp']
            description = 'Main command for BreedablePets'
            permission = 'breedablepets.command'
            permissionMessage = 'You do not have permission: breedablepets.command'
            usage = '/<command> [ help | parrotegg [fertile]]'
        }
    }
    permissions {
        'breedablepets.command' {
            description = 'Allows main command'
            defaults = 'op'
        }
        'breedablepets.*' {
            description = 'Wildcard permission'
            defaults = 'op'
            children = ['breedablepets.command': true, 'breedablepets.command.parrot': true, 'breedabpepets.reload': true]
        }
    }
}
compileJava.options.encoding = 'UTF-8' // Encode your source code with UTF-8