build.gradle

buildscript {
    repositories {
        maven { url = 'https://files.minecraftforge.net/maven' }
        maven { url = 'https://repo.spongepowered.org/maven' }
        jcenter()
        mavenCentral()
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
        classpath 'org.spongepowered:mixingradle:0.6-SNAPSHOT'
    }
}

apply plugin: 'net.minecraftforge.gradle.forge'
apply plugin: 'org.spongepowered.mixin'

version = "0.1"
group = "zone.rong"
archivesBaseName = "zairyou"

sourceCompatibility = targetCompatibility = '1.8'
compileJava {
    sourceCompatibility = targetCompatibility = '1.8'
}

minecraft {
    version = "1.12.2-14.23.5.2847"
    runDir = "run"
    mappings = "snapshot_20171003"
    def args = [
            '-Dfml.coreMods.load=zone.rong.zairyou.ZairyouCoreMod',
            '-Dmixin.hotSwap=true',
            '-Dmixin.checks.interfaces=true'
    ]
    clientJvmArgs.addAll(args)
    serverJvmArgs.addAll(args)
    useDepAts = true
}

configurations {
    embed
    implementation.extendsFrom(embed)
}

repositories {
    maven {
        url = 'https://repo.spongepowered.org/maven'
    }
    maven {
        url = "https://www.cursemaven.com"
    }
}

dependencies {

    embed ('org.spongepowered:mixin:0.8.1-SNAPSHOT') { // Don't include in the build
        transitive = false
    }

    deobfCompile "curse.maven:tfcraft-302973:3218034"

    deobfCompile "curse.maven:jei-238222:3043174"

}

jar {
    from (configurations.embed.collect { it.isDirectory() ? it : zipTree(it) }) {
        exclude 'LICENSE.txt', 'META-INF/MANIFSET.MF', 'META-INF/maven/**', 'META-INF/*.RSA', 'META-INF/*.SF'
    }
    manifest {
        attributes([
                "FMLCorePluginContainsFMLMod": true,
                "FMLCorePlugin": 'zone.rong.zairyou.ZairyouCoreMod',
                "ForceLoadAsMod": true,
                "TweakClass": 'org.spongepowered.asm.launch.MixinTweaker',
                "FMLAT": "lolilib_at.cfg"
        ])
    }
}

sourceSets {
    main {
        ext.refMap = 'mixins.zairyou.refmap.json'
    }
}

processResources {
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }
        
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }

    rename '(.+_at.cfg)', 'META-INF/$1'
}