build.gradle

plugins {
    id 'java'
    id 'application'
    id 'jacoco'
}

import org.gradle.api.tasks.testing.logging.TestLogEvent

tasks.named('wrapper') {
    gradleVersion = "6.7"
    distributionType = Wrapper.DistributionType.ALL
}

java {
    sourceCompatibility = JavaVersion.VERSION_15
    targetCompatibility = JavaVersion.VERSION_15
}

test {
    useTestNG()
    testLogging {
        events TestLogEvent.STARTED, TestLogEvent.PASSED, TestLogEvent.SKIPPED, TestLogEvent.FAILED
    }
}

tasks.withType(JavaCompile) {
    options.compilerArgs += "--enable-preview"
}
tasks.withType(Test) {
    jvmArgs += "--enable-preview"
}
tasks.withType(JavaExec) {
    jvmArgs += "--enable-preview"
}

repositories {
    mavenCentral()
}

dependencies {
    implementation "org.apache.commons:commons-lang3:3.11"
    implementation "org.slf4j:slf4j-api:2.0.0-alpha1"
    implementation "com.google.guava:guava:30.0-jre"
    implementation "com.squareup.okhttp3:okhttp:4.10.0-RC1"

    runtimeOnly "org.apache.logging.log4j:log4j-slf4j18-impl:2.14.0"

    testImplementation "com.squareup.okhttp3:mockwebserver:4.10.0-RC1"
    testImplementation "org.mockito:mockito-core:3.6.0"
    testImplementation "org.testng:testng:7.3.0"
}

application {
    mainClassName = "net.akaritakai.aoc2020.Main"
}

jacoco {
    toolVersion = "0.8.6"
}

jacocoTestReport {
    reports {
        xml.enabled = true
        html.enabled = true
    }
}

check.dependsOn jacocoTestReport